source: ntrip/trunk/BNC/src/src.pri@ 8646

Last change on this file since 8646 was 8267, checked in by stuerze, 7 years ago

minor changes to try to reanimate the qDebug output again
File size: 7.0 KB
Line 
1
2unix:DEFINES += _TTY_POSIX_
3win32:DEFINES += _TTY_WIN_
4
5RESOURCES += bnc.qrc
6
7QT += svg
8QT += printsupport
9greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
10greaterThan(QT_MAJOR_VERSION, 4): QT += core
11
12unix:QMAKE_CFLAGS_RELEASE -= -O2
13unix:QMAKE_CXXFLAGS_RELEASE -= -O2
14
15# Get rid of mingwm10.dll and libgcc_s_dw2-1.dll
16# ----------------------------------------------
17win32 {
18 QMAKE_LFLAGS += -static-libgcc
19 QMAKE_LFLAGS -= -mthreads
20 QMAKE_CXXFLAGS_EXCEPTIONS_ON -= -mthreads
21 QMAKE_LFLAGS_EXCEPTIONS_ON -= -mthreads
22}
23
24debug:OBJECTS_DIR=.obj/debug
25debug:MOC_DIR=.moc/debug
26release:OBJECTS_DIR=.obj/release
27release:MOC_DIR=.moc/release
28
29debug:DEFINES += BNC_DEBUG
30
31# Include Path
32# ------------
33INCLUDEPATH += . ../newmat ./RTCM3 ./RTCM3/clock_and_orbit ./RTCM \
34 ../qwt ../qwtpolar
35
36# Additional Libraries
37# --------------------
38unix:LIBS += -L../newmat -lnewmat -L../qwt -L../qwtpolar -lqwtpolar -lqwt
39win32:LIBS += -L../newmat/release -L../qwt/release -L../qwtpolar/release \
40 -lnewmat -lqwtpolar -lqwt
41
42HEADERS = bnchelp.html bncgetthread.h bncwindow.h bnctabledlg.h \
43 bnccaster.h bncrinex.h bnccore.h bncutils.h bnchlpdlg.h \
44 bncconst.h bnchtml.h bnctableitem.h bnczerodecoder.h \
45 bncnetquery.h bncnetqueryv1.h bncnetqueryv2.h \
46 bncnetqueryrtp.h bncsettings.h latencychecker.h \
47 bncipport.h bncnetqueryv0.h bncnetqueryudp.h \
48 bncnetqueryudp0.h bncudpport.h bnctime.h \
49 bncserialport.h bncnetquerys.h bncfigure.h \
50 bncfigurelate.h bncversion.h \
51 bncfigureppp.h bncrawfile.h \
52 bncmap.h bncantex.h bncephuser.h \
53 bncoutf.h bncclockrinex.h bncsp3.h bncsinextro.h \
54 bncbytescounter.h bncsslconfig.h reqcdlg.h \
55 upload/bncrtnetdecoder.h upload/bncuploadcaster.h \
56 ephemeris.h t_prn.h satObs.h \
57 upload/bncrtnetuploadcaster.h upload/bnccustomtrafo.h \
58 upload/bncephuploadcaster.h qtfilechooser.h \
59 GPSDecoder.h pppInclude.h pppWidgets.h pppModel.h \
60 pppMain.h pppRun.h pppOptions.h pppCrdFile.h pppThread.h \
61 RTCM/RTCM2.h RTCM/RTCM2Decoder.h \
62 RTCM/RTCM2_2021.h RTCM/rtcm_utils.h \
63 RTCM3/RTCM3Decoder.h RTCM3/bits.h RTCM3/gnss.h \
64 RTCM3/RTCM3coDecoder.h RTCM3/ephEncoder.h \
65 RTCM3/clock_and_orbit/clock_orbit_rtcm.h \
66 rinex/rnxobsfile.h \
67 rinex/rnxnavfile.h rinex/corrfile.h \
68 rinex/reqcedit.h rinex/reqcanalyze.h \
69 rinex/graphwin.h rinex/polarplot.h \
70 rinex/availplot.h rinex/eleplot.h \
71 rinex/dopplot.h orbComp/sp3Comp.h \
72 combination/bnccomb.h
73
74HEADERS += serial/qextserialbase.h serial/qextserialport.h
75unix:HEADERS += serial/posix_qextserialport.h
76win32:HEADERS += serial/win_qextserialport.h
77
78SOURCES = bncgetthread.cpp bncwindow.cpp bnctabledlg.cpp \
79 bnccaster.cpp bncrinex.cpp bnccore.cpp bncutils.cpp \
80 bncconst.cpp bnchtml.cpp bnchlpdlg.cpp bnctableitem.cpp \
81 bnczerodecoder.cpp bncnetqueryv1.cpp bncnetqueryv2.cpp \
82 bncnetqueryrtp.cpp bncsettings.cpp latencychecker.cpp \
83 bncipport.cpp bncnetqueryv0.cpp bncnetqueryudp.cpp \
84 bncnetqueryudp0.cpp bncudpport.cpp \
85 bncserialport.cpp bncnetquerys.cpp bncfigure.cpp \
86 bncfigurelate.cpp bnctime.cpp \
87 bncfigureppp.cpp bncrawfile.cpp \
88 bncmap_svg.cpp bncantex.cpp bncephuser.cpp \
89 bncoutf.cpp bncclockrinex.cpp bncsp3.cpp bncsinextro.cpp \
90 bncbytescounter.cpp bncsslconfig.cpp reqcdlg.cpp \
91 ephemeris.cpp t_prn.cpp satObs.cpp \
92 upload/bncrtnetdecoder.cpp upload/bncuploadcaster.cpp \
93 upload/bncrtnetuploadcaster.cpp upload/bnccustomtrafo.cpp \
94 upload/bncephuploadcaster.cpp qtfilechooser.cpp \
95 GPSDecoder.cpp pppWidgets.cpp pppModel.cpp \
96 pppMain.cpp pppRun.cpp pppOptions.cpp pppCrdFile.cpp \
97 pppThread.cpp \
98 RTCM/RTCM2.cpp RTCM/RTCM2Decoder.cpp \
99 RTCM/RTCM2_2021.cpp RTCM/rtcm_utils.cpp \
100 RTCM3/RTCM3Decoder.cpp \
101 RTCM3/RTCM3coDecoder.cpp RTCM3/ephEncoder.cpp \
102 RTCM3/clock_and_orbit/clock_orbit_rtcm.c \
103 rinex/rnxobsfile.cpp \
104 rinex/rnxnavfile.cpp rinex/corrfile.cpp \
105 rinex/reqcedit.cpp rinex/reqcanalyze.cpp \
106 rinex/graphwin.cpp rinex/polarplot.cpp \
107 rinex/availplot.cpp rinex/eleplot.cpp \
108 rinex/dopplot.cpp orbComp/sp3Comp.cpp \
109 combination/bnccomb.cpp
110
111SOURCES += serial/qextserialbase.cpp serial/qextserialport.cpp
112unix:SOURCES += serial/posix_qextserialport.cpp
113win32:SOURCES += serial/win_qextserialport.cpp
114
115RC_FILE = bnc.rc
116
117QT += network
118
119exists(PPP) {
120 INCLUDEPATH += PPP
121 DEFINES += USE_PPP
122 HEADERS += PPP/pppClient.h PPP/pppObsPool.h PPP/pppEphPool.h \
123 PPP/pppStation.h PPP/pppFilter.h PPP/pppParlist.h \
124 PPP/pppSatObs.h
125 SOURCES += PPP/pppClient.cpp PPP/pppObsPool.cpp PPP/pppEphPool.cpp \
126 PPP/pppStation.cpp PPP/pppFilter.cpp PPP/pppParlist.cpp \
127 PPP/pppSatObs.cpp
128}
129else {
130 INCLUDEPATH += PPP_SSR_I
131 DEFINES += USE_PPP_SSR_I
132 HEADERS += PPP_SSR_I/pppClient.h PPP_SSR_I/pppFilter.h PPP_SSR_I/pppUtils.h
133 SOURCES += PPP_SSR_I/pppClient.cpp PPP_SSR_I/pppFilter.cpp PPP_SSR_I/pppUtils.cpp
134}
135
136# Check QtWebKit Library Existence
137# --------------------------------
138exists("$$[QT_INSTALL_LIBS]/*WebKit*") {
139 DEFINES += QT_WEBKIT
140 QT += webkit webkitwidgets
141 message("Configured with QtWebKit")
142}
143
144exists("$$[QT_INSTALL_LIBS]/*WebEngineWidgets*") {
145 DEFINES += QT_WEBENGINE
146 QT += webenginewidgets
147 message("Configured with QtWebEngine")
148}
149
150contains(DEFINES, QT_WEBENGINE) | contains(DEFINES, QT_WEBKIT) {
151 HEADERS += map/bncmapwin.h
152 SOURCES += map/bncmapwin.cpp
153 OTHER_FILES += map/map_gm.html map/map_osm.html
154}
155else {
156 message("Neither QtWebEngine nor QtWebKit is available")
157}
Note: See TracBrowser for help on using the repository browser.