source: ntrip/trunk/BNC/src/src.pri@ 8264

Last change on this file since 8264 was 8264, checked in by stuerze, 4 years ago

see #105: adaptations to allow for QtWebkit or QtWebEngine according to it's availability in qt4 and 5

File size: 6.9 KB
Line 
1
2unix:DEFINES += _TTY_POSIX_
3win32:DEFINES += _TTY_WIN_
4
5RESOURCES += bnc.qrc
6
7QT += svg
8QT += printsupport
9greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
10
11unix:QMAKE_CFLAGS_RELEASE -= -O2
12unix:QMAKE_CXXFLAGS_RELEASE -= -O2
13
14# Get rid of mingwm10.dll and libgcc_s_dw2-1.dll
15# ----------------------------------------------
16win32 {
17 QMAKE_LFLAGS += -static-libgcc
18 QMAKE_LFLAGS -= -mthreads
19 QMAKE_CXXFLAGS_EXCEPTIONS_ON -= -mthreads
20 QMAKE_LFLAGS_EXCEPTIONS_ON -= -mthreads
21}
22
23debug:OBJECTS_DIR=.obj/debug
24debug:MOC_DIR=.moc/debug
25release:OBJECTS_DIR=.obj/release
26release:MOC_DIR=.moc/release
27
28debug:DEFINES += BNC_DEBUG
29
30# Include Path
31# ------------
32INCLUDEPATH += . ../newmat ./RTCM3 ./RTCM3/clock_and_orbit ./RTCM \
33 ../qwt ../qwtpolar
34
35# Additional Libraries
36# --------------------
37unix:LIBS += -L../newmat -lnewmat -L../qwt -L../qwtpolar -lqwtpolar -lqwt
38win32:LIBS += -L../newmat/release -L../qwt/release -L../qwtpolar/release \
39 -lnewmat -lqwtpolar -lqwt
40
41HEADERS = bnchelp.html bncgetthread.h bncwindow.h bnctabledlg.h \
42 bnccaster.h bncrinex.h bnccore.h bncutils.h bnchlpdlg.h \
43 bncconst.h bnchtml.h bnctableitem.h bnczerodecoder.h \
44 bncnetquery.h bncnetqueryv1.h bncnetqueryv2.h \
45 bncnetqueryrtp.h bncsettings.h latencychecker.h \
46 bncipport.h bncnetqueryv0.h bncnetqueryudp.h \
47 bncnetqueryudp0.h bncudpport.h bnctime.h \
48 bncserialport.h bncnetquerys.h bncfigure.h \
49 bncfigurelate.h bncversion.h \
50 bncfigureppp.h bncrawfile.h \
51 bncmap.h bncantex.h bncephuser.h \
52 bncoutf.h bncclockrinex.h bncsp3.h bncsinextro.h \
53 bncbytescounter.h bncsslconfig.h reqcdlg.h \
54 upload/bncrtnetdecoder.h upload/bncuploadcaster.h \
55 ephemeris.h t_prn.h satObs.h \
56 upload/bncrtnetuploadcaster.h upload/bnccustomtrafo.h \
57 upload/bncephuploadcaster.h qtfilechooser.h \
58 GPSDecoder.h pppInclude.h pppWidgets.h pppModel.h \
59 pppMain.h pppRun.h pppOptions.h pppCrdFile.h pppThread.h \
60 RTCM/RTCM2.h RTCM/RTCM2Decoder.h \
61 RTCM/RTCM2_2021.h RTCM/rtcm_utils.h \
62 RTCM3/RTCM3Decoder.h RTCM3/bits.h RTCM3/gnss.h \
63 RTCM3/RTCM3coDecoder.h RTCM3/ephEncoder.h \
64 RTCM3/clock_and_orbit/clock_orbit_rtcm.h \
65 rinex/rnxobsfile.h \
66 rinex/rnxnavfile.h rinex/corrfile.h \
67 rinex/reqcedit.h rinex/reqcanalyze.h \
68 rinex/graphwin.h rinex/polarplot.h \
69 rinex/availplot.h rinex/eleplot.h \
70 rinex/dopplot.h orbComp/sp3Comp.h \
71 combination/bnccomb.h
72
73HEADERS += serial/qextserialbase.h serial/qextserialport.h
74unix:HEADERS += serial/posix_qextserialport.h
75win32:HEADERS += serial/win_qextserialport.h
76
77SOURCES = bncgetthread.cpp bncwindow.cpp bnctabledlg.cpp \
78 bnccaster.cpp bncrinex.cpp bnccore.cpp bncutils.cpp \
79 bncconst.cpp bnchtml.cpp bnchlpdlg.cpp bnctableitem.cpp \
80 bnczerodecoder.cpp bncnetqueryv1.cpp bncnetqueryv2.cpp \
81 bncnetqueryrtp.cpp bncsettings.cpp latencychecker.cpp \
82 bncipport.cpp bncnetqueryv0.cpp bncnetqueryudp.cpp \
83 bncnetqueryudp0.cpp bncudpport.cpp \
84 bncserialport.cpp bncnetquerys.cpp bncfigure.cpp \
85 bncfigurelate.cpp bnctime.cpp \
86 bncfigureppp.cpp bncrawfile.cpp \
87 bncmap_svg.cpp bncantex.cpp bncephuser.cpp \
88 bncoutf.cpp bncclockrinex.cpp bncsp3.cpp bncsinextro.cpp \
89 bncbytescounter.cpp bncsslconfig.cpp reqcdlg.cpp \
90 ephemeris.cpp t_prn.cpp satObs.cpp \
91 upload/bncrtnetdecoder.cpp upload/bncuploadcaster.cpp \
92 upload/bncrtnetuploadcaster.cpp upload/bnccustomtrafo.cpp \
93 upload/bncephuploadcaster.cpp qtfilechooser.cpp \
94 GPSDecoder.cpp pppWidgets.cpp pppModel.cpp \
95 pppMain.cpp pppRun.cpp pppOptions.cpp pppCrdFile.cpp \
96 pppThread.cpp \
97 RTCM/RTCM2.cpp RTCM/RTCM2Decoder.cpp \
98 RTCM/RTCM2_2021.cpp RTCM/rtcm_utils.cpp \
99 RTCM3/RTCM3Decoder.cpp \
100 RTCM3/RTCM3coDecoder.cpp RTCM3/ephEncoder.cpp \
101 RTCM3/clock_and_orbit/clock_orbit_rtcm.c \
102 rinex/rnxobsfile.cpp \
103 rinex/rnxnavfile.cpp rinex/corrfile.cpp \
104 rinex/reqcedit.cpp rinex/reqcanalyze.cpp \
105 rinex/graphwin.cpp rinex/polarplot.cpp \
106 rinex/availplot.cpp rinex/eleplot.cpp \
107 rinex/dopplot.cpp orbComp/sp3Comp.cpp \
108 combination/bnccomb.cpp
109
110SOURCES += serial/qextserialbase.cpp serial/qextserialport.cpp
111unix:SOURCES += serial/posix_qextserialport.cpp
112win32:SOURCES += serial/win_qextserialport.cpp
113
114RC_FILE = bnc.rc
115
116QT += network
117
118exists(PPP) {
119 INCLUDEPATH += PPP
120 DEFINES += USE_PPP
121 HEADERS += PPP/pppClient.h PPP/pppObsPool.h PPP/pppEphPool.h \
122 PPP/pppStation.h PPP/pppFilter.h PPP/pppParlist.h \
123 PPP/pppSatObs.h
124 SOURCES += PPP/pppClient.cpp PPP/pppObsPool.cpp PPP/pppEphPool.cpp \
125 PPP/pppStation.cpp PPP/pppFilter.cpp PPP/pppParlist.cpp \
126 PPP/pppSatObs.cpp
127}
128else {
129 INCLUDEPATH += PPP_SSR_I
130 DEFINES += USE_PPP_SSR_I
131 HEADERS += PPP_SSR_I/pppClient.h PPP_SSR_I/pppFilter.h PPP_SSR_I/pppUtils.h
132 SOURCES += PPP_SSR_I/pppClient.cpp PPP_SSR_I/pppFilter.cpp PPP_SSR_I/pppUtils.cpp
133}
134
135# Check QtWebKit Library Existence
136# --------------------------------
137exists("$$[QT_INSTALL_LIBS]/*WebKit*") {
138 DEFINES += QT_WEBKIT
139 QT += webkit webkitwidgets
140 message("Configured with QtWebKit")
141}
142
143exists("$$[QT_INSTALL_LIBS]/*WebEngineWidgets*") {
144 DEFINES += QT_WEBENGINE
145 QT += webenginewidgets
146 message("Configured with QtWebEngine")
147}
148
149contains(DEFINES, QT_WEBENGINE) | contains(DEFINES, QT_WEBKIT) {
150 HEADERS += map/bncmapwin.h
151 SOURCES += map/bncmapwin.cpp
152 OTHER_FILES += map/map_gm.html map/map_osm.html
153}
154else {
155 message("Neither QtWebEngine nor QtWebKit is available")
156}
Note: See TracBrowser for help on using the repository browser.