source: ntrip/trunk/BNC/src/src.pro@ 5071

Last change on this file since 5071 was 5071, checked in by mervart, 9 years ago
File size: 6.1 KB
Line 
1
2QT += svg
3
4TARGET = ../bnc
5
6# Switch to debug configuration
7# -----------------------------
8CONFIG -= debug
9CONFIG += release
10
11DEFINES += NO_RTCM3_MAIN
12###DEFINES += DEBUG_RTCM2_2021
13unix:DEFINES += _TTY_POSIX_
14win32:DEFINES += _TTY_WIN_
15
16RESOURCES += bnc.qrc
17
18unix:QMAKE_CFLAGS_RELEASE -= -O2
19unix:QMAKE_CXXFLAGS_RELEASE -= -O2
20
21# Get rid of mingwm10.dll and libgcc_s_dw2-1.dll
22# ----------------------------------------------
23win32 {
24 QMAKE_LFLAGS += -static-libgcc
25 QMAKE_LFLAGS -= -mthreads
26 QMAKE_CXXFLAGS_EXCEPTIONS_ON -= -mthreads
27 QMAKE_LFLAGS_EXCEPTIONS_ON -= -mthreads
28}
29
30debug:OBJECTS_DIR=.obj/debug
31debug:MOC_DIR=.moc/debug
32release:OBJECTS_DIR=.obj/release
33release:MOC_DIR=.moc/release
34
35# Include Path
36# ------------
37INCLUDEPATH = . ../newmat ./RTCM3 ./RTCM3/clock_and_orbit ./RTCM3/rtcm3torinex \
38 ../qwt ../qwtpolar
39
40# Additional Libraries
41# --------------------
42unix:LIBS += -L../newmat -lnewmat -L../qwt -L../qwtpolar -lqwtpolar -lqwt
43win32:LIBS += -L../newmat/release -L../qwt/release -L../qwtpolar/release \
44 -lnewmat -lqwtpolar -lqwt
45
46HEADERS = bnchelp.html bncgetthread.h bncwindow.h bnctabledlg.h \
47 bnccaster.h bncrinex.h bnccore.h bncutils.h bnchlpdlg.h \
48 bncconst.h bnchtml.h bnctableitem.h bnczerodecoder.h \
49 bncnetquery.h bncnetqueryv1.h bncnetqueryv2.h \
50 bncnetqueryrtp.h bncsettings.h latencychecker.h \
51 bncipport.h bncnetqueryv0.h bncnetqueryudp.h \
52 bncnetqueryudp0.h bncudpport.h bnctime.h pppopt.h \
53 bncserialport.h bncnetquerys.h bncfigure.h \
54 bncfigurelate.h bncpppclient.h bncversion.h \
55 bancroft.h bncmodel.h bncfigureppp.h bncrawfile.h \
56 bnctides.h bncmap.h bncantex.h \
57 bncephuser.h bncoutf.h bncclockrinex.h bncsp3.h \
58 bncbytescounter.h bncsslconfig.h reqcdlg.h \
59 app.h \
60 upload/bncrtnetdecoder.h upload/bncuploadcaster.h \
61 upload/bncrtnetuploadcaster.h upload/bnccustomtrafo.h \
62 upload/bncephuploadcaster.h bnccomb.h qtfilechooser.h \
63 RTCM/GPSDecoder.h RTCM/RTCM2.h RTCM/RTCM2Decoder.h \
64 RTCM/RTCM2_2021.h RTCM/rtcm_utils.h \
65 RTCM3/RTCM3Decoder.h RTCM3/rtcm3torinex/rtcm3torinex.h \
66 RTCM3/rtcm3torinex/rtcm3torinexsupport.h \
67 RTCM3/RTCM3coDecoder.h \
68 RTCM3/clock_and_orbit/clock_orbit_rtcm.h \
69 RTCM3/ephemeris.h RTCM3/timeutils.h \
70 GPSS/gpssDecoder.h GPSS/hassDecoder.h
71
72HEADERS += serial/qextserialbase.h serial/qextserialport.h
73unix:HEADERS += serial/posix_qextserialport.h
74win32:HEADERS += serial/win_qextserialport.h
75
76SOURCES = bncmain.cpp bncgetthread.cpp bncwindow.cpp bnctabledlg.cpp \
77 bnccaster.cpp bncrinex.cpp bnccore.cpp bncutils.cpp \
78 bncconst.cpp bnchtml.cpp bnchlpdlg.cpp bnctableitem.cpp \
79 bnczerodecoder.cpp bncnetqueryv1.cpp bncnetqueryv2.cpp \
80 bncnetqueryrtp.cpp bncsettings.cpp latencychecker.cpp \
81 bncipport.cpp bncnetqueryv0.cpp bncnetqueryudp.cpp \
82 bncnetqueryudp0.cpp bncudpport.cpp pppopt.cpp \
83 bncserialport.cpp bncnetquerys.cpp bncfigure.cpp \
84 bncfigurelate.cpp bncpppclient.cpp bnctime.cpp \
85 bancroft.cpp bncmodel.cpp bncfigureppp.cpp bncrawfile.cpp \
86 bnctides.cpp bncmap_svg.cpp bncantex.cpp \
87 bncephuser.cpp bncoutf.cpp bncclockrinex.cpp bncsp3.cpp \
88 bncbytescounter.cpp bncsslconfig.cpp reqcdlg.cpp \
89 app.cpp \
90 upload/bncrtnetdecoder.cpp upload/bncuploadcaster.cpp \
91 upload/bncrtnetuploadcaster.cpp upload/bnccustomtrafo.cpp \
92 upload/bncephuploadcaster.cpp qtfilechooser.cpp \
93 RTCM/GPSDecoder.cpp RTCM/RTCM2.cpp RTCM/RTCM2Decoder.cpp \
94 RTCM/RTCM2_2021.cpp RTCM/rtcm_utils.cpp \
95 RTCM3/RTCM3Decoder.cpp RTCM3/rtcm3torinex/rtcm3torinex.c \
96 RTCM3/rtcm3torinex/rtcm3torinexsupport.c \
97 RTCM3/RTCM3coDecoder.cpp \
98 RTCM3/clock_and_orbit/clock_orbit_rtcm.c \
99 RTCM3/ephemeris.cpp RTCM3/timeutils.cpp \
100 GPSS/gpssDecoder.cpp GPSS/hassDecoder.cpp
101
102SOURCES += serial/qextserialbase.cpp serial/qextserialport.cpp
103unix:SOURCES += serial/posix_qextserialport.cpp
104win32:SOURCES += serial/win_qextserialport.cpp
105
106RC_FILE = bnc.rc
107
108QT += network
109
110exists(combination/bnccomb.h) {
111 DEFINES += USE_COMBINATION
112 HEADERS += combination/bnccomb.h
113 SOURCES += combination/bnccomb.cpp
114}
115
116exists(rinex/bncpostprocess.h) {
117 DEFINES += USE_POSTPROCESSING
118 HEADERS += rinex/bncpostprocess.h rinex/rnxobsfile.h \
119 rinex/rnxnavfile.h rinex/corrfile.h \
120 rinex/reqcedit.h rinex/reqcanalyze.h \
121 rinex/graphwin.h rinex/polarplot.h \
122 rinex/availplot.h rinex/eleplot.h \
123 rinex/dopplot.h
124 SOURCES += rinex/bncpostprocess.cpp rinex/rnxobsfile.cpp \
125 rinex/rnxnavfile.cpp rinex/corrfile.cpp \
126 rinex/reqcedit.cpp rinex/reqcanalyze.cpp \
127 rinex/graphwin.cpp rinex/polarplot.cpp \
128 rinex/availplot.cpp rinex/eleplot.cpp \
129 rinex/dopplot.cpp
130}
131
132# Link to a 3rd-part library (test)
133# ---------------------------------
134# use_RTRover = true
135
136equals(use_RTRover, true) {
137 DEFINES += RTROVER_INTERFACE
138 HEADERS += RTRover/bncrtrover.h
139 SOURCES += RTRover/bncrtrover.cpp
140 LIBS += -LRTRover -lRTRover
141 unix:LIBS += -Wl,-rpath,$$PWD/RTRover
142}
143
Note: See TracBrowser for help on using the repository browser.