source: ntrip/trunk/BNC/src/src.pri@ 7855

Last change on this file since 7855 was 7761, checked in by stuerze, 8 years ago

some redundant entries deleted

File size: 6.8 KB
Line 
1
2unix:DEFINES += _TTY_POSIX_
3win32:DEFINES += _TTY_WIN_
4
5RESOURCES += bnc.qrc
6
7QT += svg
8
9unix:QMAKE_CFLAGS_RELEASE -= -O2
10unix:QMAKE_CXXFLAGS_RELEASE -= -O2
11
12# Get rid of mingwm10.dll and libgcc_s_dw2-1.dll
13# ----------------------------------------------
14win32 {
15 QMAKE_LFLAGS += -static-libgcc
16 QMAKE_LFLAGS -= -mthreads
17 QMAKE_CXXFLAGS_EXCEPTIONS_ON -= -mthreads
18 QMAKE_LFLAGS_EXCEPTIONS_ON -= -mthreads
19}
20
21debug:OBJECTS_DIR=.obj/debug
22debug:MOC_DIR=.moc/debug
23release:OBJECTS_DIR=.obj/release
24release:MOC_DIR=.moc/release
25
26# Include Path
27# ------------
28INCLUDEPATH += . ../newmat ./RTCM3 ./RTCM3/clock_and_orbit ./RTCM \
29 ../qwt ../qwtpolar
30
31# Additional Libraries
32# --------------------
33unix:LIBS += -L../newmat -lnewmat -L../qwt -L../qwtpolar -lqwtpolar -lqwt
34win32:LIBS += -L../newmat/release -L../qwt/release -L../qwtpolar/release \
35 -lnewmat -lqwtpolar -lqwt
36
37HEADERS = bnchelp.html bncgetthread.h bncwindow.h bnctabledlg.h \
38 bnccaster.h bncrinex.h bnccore.h bncutils.h bnchlpdlg.h \
39 bncconst.h bnchtml.h bnctableitem.h bnczerodecoder.h \
40 bncnetquery.h bncnetqueryv1.h bncnetqueryv2.h \
41 bncnetqueryrtp.h bncsettings.h latencychecker.h \
42 bncipport.h bncnetqueryv0.h bncnetqueryudp.h \
43 bncnetqueryudp0.h bncudpport.h bnctime.h \
44 bncserialport.h bncnetquerys.h bncfigure.h \
45 bncfigurelate.h bncversion.h \
46 bncfigureppp.h bncrawfile.h \
47 bncmap.h bncantex.h bncephuser.h \
48 bncoutf.h bncclockrinex.h bncsp3.h bncsinextro.h \
49 bncbytescounter.h bncsslconfig.h reqcdlg.h \
50 upload/bncrtnetdecoder.h upload/bncuploadcaster.h \
51 ephemeris.h t_prn.h satObs.h \
52 upload/bncrtnetuploadcaster.h upload/bnccustomtrafo.h \
53 upload/bncephuploadcaster.h qtfilechooser.h \
54 GPSDecoder.h pppInclude.h pppWidgets.h pppModel.h \
55 pppMain.h pppRun.h pppOptions.h pppCrdFile.h pppThread.h \
56 RTCM/RTCM2.h RTCM/RTCM2Decoder.h \
57 RTCM/RTCM2_2021.h RTCM/rtcm_utils.h \
58 RTCM3/RTCM3Decoder.h RTCM3/bits.h RTCM3/gnss.h \
59 RTCM3/RTCM3coDecoder.h RTCM3/ephEncoder.h \
60 RTCM3/clock_and_orbit/clock_orbit_rtcm.h \
61 rinex/rnxobsfile.h \
62 rinex/rnxnavfile.h rinex/corrfile.h \
63 rinex/reqcedit.h rinex/reqcanalyze.h \
64 rinex/graphwin.h rinex/polarplot.h \
65 rinex/availplot.h rinex/eleplot.h \
66 rinex/dopplot.h orbComp/sp3Comp.h \
67 combination/bnccomb.h
68
69HEADERS += serial/qextserialbase.h serial/qextserialport.h
70unix:HEADERS += serial/posix_qextserialport.h
71win32:HEADERS += serial/win_qextserialport.h
72
73SOURCES = bncgetthread.cpp bncwindow.cpp bnctabledlg.cpp \
74 bnccaster.cpp bncrinex.cpp bnccore.cpp bncutils.cpp \
75 bncconst.cpp bnchtml.cpp bnchlpdlg.cpp bnctableitem.cpp \
76 bnczerodecoder.cpp bncnetqueryv1.cpp bncnetqueryv2.cpp \
77 bncnetqueryrtp.cpp bncsettings.cpp latencychecker.cpp \
78 bncipport.cpp bncnetqueryv0.cpp bncnetqueryudp.cpp \
79 bncnetqueryudp0.cpp bncudpport.cpp \
80 bncserialport.cpp bncnetquerys.cpp bncfigure.cpp \
81 bncfigurelate.cpp bnctime.cpp \
82 bncfigureppp.cpp bncrawfile.cpp \
83 bncmap_svg.cpp bncantex.cpp bncephuser.cpp \
84 bncoutf.cpp bncclockrinex.cpp bncsp3.cpp bncsinextro.cpp \
85 bncbytescounter.cpp bncsslconfig.cpp reqcdlg.cpp \
86 ephemeris.cpp t_prn.cpp satObs.cpp \
87 upload/bncrtnetdecoder.cpp upload/bncuploadcaster.cpp \
88 upload/bncrtnetuploadcaster.cpp upload/bnccustomtrafo.cpp \
89 upload/bncephuploadcaster.cpp qtfilechooser.cpp \
90 GPSDecoder.cpp pppWidgets.cpp pppModel.cpp \
91 pppMain.cpp pppRun.cpp pppOptions.cpp pppCrdFile.cpp \
92 pppThread.cpp \
93 RTCM/RTCM2.cpp RTCM/RTCM2Decoder.cpp \
94 RTCM/RTCM2_2021.cpp RTCM/rtcm_utils.cpp \
95 RTCM3/RTCM3Decoder.cpp \
96 RTCM3/RTCM3coDecoder.cpp RTCM3/ephEncoder.cpp \
97 RTCM3/clock_and_orbit/clock_orbit_rtcm.c \
98 rinex/rnxobsfile.cpp \
99 rinex/rnxnavfile.cpp rinex/corrfile.cpp \
100 rinex/reqcedit.cpp rinex/reqcanalyze.cpp \
101 rinex/graphwin.cpp rinex/polarplot.cpp \
102 rinex/availplot.cpp rinex/eleplot.cpp \
103 rinex/dopplot.cpp orbComp/sp3Comp.cpp \
104 combination/bnccomb.cpp
105
106SOURCES += serial/qextserialbase.cpp serial/qextserialport.cpp
107unix:SOURCES += serial/posix_qextserialport.cpp
108win32:SOURCES += serial/win_qextserialport.cpp
109
110RC_FILE = bnc.rc
111
112QT += network
113
114exists(PPP) {
115 INCLUDEPATH += PPP
116 DEFINES += USE_PPP
117 HEADERS += PPP/pppClient.h PPP/pppObsPool.h PPP/pppEphPool.h \
118 PPP/pppStation.h PPP/pppFilter.h PPP/pppParlist.h \
119 PPP/pppSatObs.h
120 SOURCES += PPP/pppClient.cpp PPP/pppObsPool.cpp PPP/pppEphPool.cpp \
121 PPP/pppStation.cpp PPP/pppFilter.cpp PPP/pppParlist.cpp \
122 PPP/pppSatObs.cpp
123}
124else {
125 INCLUDEPATH += PPP_SSR_I
126 DEFINES += USE_PPP_SSR_I
127 HEADERS += PPP_SSR_I/pppClient.h PPP_SSR_I/pppFilter.h PPP_SSR_I/pppUtils.h
128 SOURCES += PPP_SSR_I/pppClient.cpp PPP_SSR_I/pppFilter.cpp PPP_SSR_I/pppUtils.cpp
129}
130
131# Check QtWebKit Library Existence
132# --------------------------------
133win32 {
134 exists("$$[QT_INSTALL_BINS]/QtWebKit4.dll") {
135 DEFINES += QT_WEBKIT
136 }
137}
138
139unix {
140 exists("$$[QT_INSTALL_LIBS]/libQtWebKit.so") {
141 DEFINES += QT_WEBKIT
142 }
143}
144
145macx {
146 exists("$$[QT_INSTALL_LIBS]/QtWebKit.framework") {
147 DEFINES += QT_WEBKIT
148 }
149}
150
151contains(DEFINES, QT_WEBKIT) {
152 message("Configured with QtWebKit")
153 QT += webkit
154 HEADERS += map/bncmapwin.h
155 SOURCES += map/bncmapwin.cpp
156 OTHER_FILES += map/map_gm.html map/map_osm.html
157}
158else {
159 message("No QtWebKit")
160}
Note: See TracBrowser for help on using the repository browser.