source: ntrip/trunk/BNC/src/src.pri@ 6044

Last change on this file since 6044 was 6044, checked in by mervart, 8 years ago
File size: 6.7 KB
Line 
1
2DEFINES += NO_RTCM3_MAIN
3unix:DEFINES += _TTY_POSIX_
4win32:DEFINES += _TTY_WIN_
5
6RESOURCES += bnc.qrc
7
8QT += svg
9
10unix:QMAKE_CFLAGS_RELEASE -= -O2
11unix:QMAKE_CXXFLAGS_RELEASE -= -O2
12
13# Get rid of mingwm10.dll and libgcc_s_dw2-1.dll
14# ----------------------------------------------
15win32 {
16 QMAKE_LFLAGS += -static-libgcc
17 QMAKE_LFLAGS -= -mthreads
18 QMAKE_CXXFLAGS_EXCEPTIONS_ON -= -mthreads
19 QMAKE_LFLAGS_EXCEPTIONS_ON -= -mthreads
20}
21
22debug:OBJECTS_DIR=.obj/debug
23debug:MOC_DIR=.moc/debug
24release:OBJECTS_DIR=.obj/release
25release:MOC_DIR=.moc/release
26
27# Include Path
28# ------------
29INCLUDEPATH += . ../newmat ./RTCM3 ./RTCM3/clock_and_orbit ./RTCM3/rtcm3torinex \
30 ../qwt ../qwtpolar
31
32# Additional Libraries
33# --------------------
34unix:LIBS += -L../newmat -lnewmat -L../qwt -L../qwtpolar -lqwtpolar -lqwt
35win32:LIBS += -L../newmat/release -L../qwt/release -L../qwtpolar/release \
36 -lnewmat -lqwtpolar -lqwt
37
38HEADERS = bnchelp.html bncgetthread.h bncwindow.h bnctabledlg.h \
39 bnccaster.h bncrinex.h bnccore.h bncutils.h bnchlpdlg.h \
40 bncconst.h bnchtml.h bnctableitem.h bnczerodecoder.h \
41 bncnetquery.h bncnetqueryv1.h bncnetqueryv2.h \
42 bncnetqueryrtp.h bncsettings.h latencychecker.h \
43 bncipport.h bncnetqueryv0.h bncnetqueryudp.h \
44 bncnetqueryudp0.h bncudpport.h bnctime.h \
45 bncserialport.h bncnetquerys.h bncfigure.h \
46 bncfigurelate.h bncversion.h \
47 bncfigureppp.h bncrawfile.h \
48 bncmap.h bncantex.h \
49 bncephuser.h bncoutf.h bncclockrinex.h bncsp3.h \
50 bncbytescounter.h bncsslconfig.h reqcdlg.h \
51 upload/bncrtnetdecoder.h upload/bncuploadcaster.h \
52 ephemeris.h t_prn.h \
53 upload/bncrtnetuploadcaster.h upload/bnccustomtrafo.h \
54 upload/bncephuploadcaster.h qtfilechooser.h \
55 GPSDecoder.h pppInclude.h pppWidgets.h pppModel.h \
56 RTCM/RTCM2.h RTCM/RTCM2Decoder.h \
57 RTCM/RTCM2_2021.h RTCM/rtcm_utils.h \
58 RTCM3/RTCM3Decoder.h RTCM3/rtcm3torinex/rtcm3torinex.h \
59 RTCM3/RTCM3coDecoder.h RTCM3/ephEncoder.h \
60 RTCM3/clock_and_orbit/clock_orbit_rtcm.h \
61 rinex/rnxobsfile.h \
62 rinex/rnxnavfile.h rinex/corrfile.h \
63 rinex/reqcedit.h rinex/reqcanalyze.h \
64 rinex/graphwin.h rinex/polarplot.h \
65 rinex/availplot.h rinex/eleplot.h \
66 rinex/dopplot.h
67
68HEADERS += serial/qextserialbase.h serial/qextserialport.h
69unix:HEADERS += serial/posix_qextserialport.h
70win32:HEADERS += serial/win_qextserialport.h
71
72SOURCES = bncgetthread.cpp bncwindow.cpp bnctabledlg.cpp \
73 bnccaster.cpp bncrinex.cpp bnccore.cpp bncutils.cpp \
74 bncconst.cpp bnchtml.cpp bnchlpdlg.cpp bnctableitem.cpp \
75 bnczerodecoder.cpp bncnetqueryv1.cpp bncnetqueryv2.cpp \
76 bncnetqueryrtp.cpp bncsettings.cpp latencychecker.cpp \
77 bncipport.cpp bncnetqueryv0.cpp bncnetqueryudp.cpp \
78 bncnetqueryudp0.cpp bncudpport.cpp \
79 bncserialport.cpp bncnetquerys.cpp bncfigure.cpp \
80 bncfigurelate.cpp bnctime.cpp \
81 bncfigureppp.cpp bncrawfile.cpp \
82 bncmap_svg.cpp bncantex.cpp \
83 bncephuser.cpp bncoutf.cpp bncclockrinex.cpp bncsp3.cpp \
84 bncbytescounter.cpp bncsslconfig.cpp reqcdlg.cpp \
85 ephemeris.cpp t_prn.cpp \
86 upload/bncrtnetdecoder.cpp upload/bncuploadcaster.cpp \
87 upload/bncrtnetuploadcaster.cpp upload/bnccustomtrafo.cpp \
88 upload/bncephuploadcaster.cpp qtfilechooser.cpp \
89 GPSDecoder.cpp pppWidgets.cpp pppModel.cpp \
90 RTCM/RTCM2.cpp RTCM/RTCM2Decoder.cpp \
91 RTCM/RTCM2_2021.cpp RTCM/rtcm_utils.cpp \
92 RTCM3/RTCM3Decoder.cpp RTCM3/rtcm3torinex/rtcm3torinex.c \
93 RTCM3/RTCM3coDecoder.cpp RTCM3/ephEncoder.cpp \
94 RTCM3/clock_and_orbit/clock_orbit_rtcm.c \
95 rinex/rnxobsfile.cpp \
96 rinex/rnxnavfile.cpp rinex/corrfile.cpp \
97 rinex/reqcedit.cpp rinex/reqcanalyze.cpp \
98 rinex/graphwin.cpp rinex/polarplot.cpp \
99 rinex/availplot.cpp rinex/eleplot.cpp \
100 rinex/dopplot.cpp
101
102SOURCES += serial/qextserialbase.cpp serial/qextserialport.cpp
103unix:SOURCES += serial/posix_qextserialport.cpp
104win32:SOURCES += serial/win_qextserialport.cpp
105
106RC_FILE = bnc.rc
107
108QT += network
109
110exists(combination/bnccomb.h) {
111 DEFINES += USE_COMBINATION
112 HEADERS += combination/bnccomb.h
113 SOURCES += combination/bnccomb.cpp
114}
115
116exists(PPP) {
117 DEFINES += USE_PPP
118 HEADERS += PPP/pppOptions.h PPP/pppMain.h \
119 PPP/pppThread.h PPP/pppClient.h \
120 PPP/pppObsPool.h PPP/pppStation.h PPP/pppFilter.h \
121 PPP/pppEphPool.h PPP/pppParlist.h \
122 PPP/pppSatObs.h PPP/pppRun.h PPP/pppCrdFile.h
123 SOURCES += PPP/pppOptions.cpp PPP/pppMain.cpp \
124 PPP/pppThread.cpp PPP/pppClient.cpp \
125 PPP/pppObsPool.cpp PPP/pppStation.cpp PPP/pppFilter.cpp \
126 PPP/pppEphPool.cpp PPP/pppParlist.cpp \
127 PPP/pppSatObs.cpp PPP/pppRun.cpp PPP/pppCrdFile.cpp
128}
129
130# Check QtWebKit Library Existence
131# --------------------------------
132win32 {
133 exists("$$[QT_INSTALL_BINS]/QtWebKit4.dll") {
134 DEFINES += QT_WEBKIT
135 }
136}
137
138unix {
139 exists("$$[QT_INSTALL_LIBS]/libQtWebKit.so") {
140 DEFINES += QT_WEBKIT
141 }
142}
143
144macx {
145 exists("$$[QT_INSTALL_LIBS]/QtWebKit.framework") {
146 DEFINES += QT_WEBKIT
147 }
148}
149
150contains(DEFINES, QT_WEBKIT) {
151 message("Configured with QtWebKit")
152 QT += webkit
153 HEADERS += map/bncmapwin.h
154 SOURCES += map/bncmapwin.cpp
155 OTHER_FILES += map/map_gm.html map/map_osm.html
156}
157else {
158 message("No QtWebKit")
159}
Note: See TracBrowser for help on using the repository browser.