source: ntrip/trunk/BNC/src/src.pri@ 5910

Last change on this file since 5910 was 5910, checked in by mervart, 8 years ago
File size: 6.7 KB
Line 
1
2DEFINES += NO_RTCM3_MAIN
3unix:DEFINES += _TTY_POSIX_
4win32:DEFINES += _TTY_WIN_
5
6RESOURCES += bnc.qrc
7
8QT += svg
9
10unix:QMAKE_CFLAGS_RELEASE -= -O2
11unix:QMAKE_CXXFLAGS_RELEASE -= -O2
12
13# Get rid of mingwm10.dll and libgcc_s_dw2-1.dll
14# ----------------------------------------------
15win32 {
16 QMAKE_LFLAGS += -static-libgcc
17 QMAKE_LFLAGS -= -mthreads
18 QMAKE_CXXFLAGS_EXCEPTIONS_ON -= -mthreads
19 QMAKE_LFLAGS_EXCEPTIONS_ON -= -mthreads
20}
21
22debug:OBJECTS_DIR=.obj/debug
23debug:MOC_DIR=.moc/debug
24release:OBJECTS_DIR=.obj/release
25release:MOC_DIR=.moc/release
26
27# Include Path
28# ------------
29INCLUDEPATH += . ../newmat ./RTCM3 ./RTCM3/clock_and_orbit ./RTCM3/rtcm3torinex \
30 ../qwt ../qwtpolar
31
32# Additional Libraries
33# --------------------
34unix:LIBS += -L../newmat -lnewmat -L../qwt -L../qwtpolar -lqwtpolar -lqwt
35win32:LIBS += -L../newmat/release -L../qwt/release -L../qwtpolar/release \
36 -lnewmat -lqwtpolar -lqwt
37
38HEADERS = bnchelp.html bncgetthread.h bncwindow.h bnctabledlg.h \
39 bnccaster.h bncrinex.h bnccore.h bncutils.h bnchlpdlg.h \
40 bncconst.h bnchtml.h bnctableitem.h bnczerodecoder.h \
41 bncnetquery.h bncnetqueryv1.h bncnetqueryv2.h \
42 bncnetqueryrtp.h bncsettings.h latencychecker.h \
43 bncipport.h bncnetqueryv0.h bncnetqueryudp.h \
44 bncnetqueryudp0.h bncudpport.h bnctime.h \
45 bncserialport.h bncnetquerys.h bncfigure.h \
46 bncfigurelate.h bncversion.h \
47 bncfigureppp.h bncrawfile.h \
48 bncmap.h bncantex.h \
49 bncephuser.h bncoutf.h bncclockrinex.h bncsp3.h \
50 bncbytescounter.h bncsslconfig.h reqcdlg.h \
51 upload/bncrtnetdecoder.h upload/bncuploadcaster.h \
52 ephemeris.h t_prn.h \
53 upload/bncrtnetuploadcaster.h upload/bnccustomtrafo.h \
54 upload/bncephuploadcaster.h qtfilechooser.h \
55 GPSDecoder.h RTCM/RTCM2.h RTCM/RTCM2Decoder.h \
56 RTCM/RTCM2_2021.h RTCM/rtcm_utils.h \
57 RTCM3/RTCM3Decoder.h RTCM3/rtcm3torinex/rtcm3torinex.h \
58 RTCM3/RTCM3coDecoder.h RTCM3/ephEncoder.h \
59 RTCM3/clock_and_orbit/clock_orbit_rtcm.h \
60 rinex/rnxobsfile.h \
61 rinex/rnxnavfile.h rinex/corrfile.h \
62 rinex/reqcedit.h rinex/reqcanalyze.h \
63 rinex/graphwin.h rinex/polarplot.h \
64 rinex/availplot.h rinex/eleplot.h \
65 rinex/dopplot.h \
66 PPP/pppInclude.h PPP/pppOptions.h PPP/pppMain.h \
67 PPP/pppWidgets.h PPP/pppThread.h PPP/pppClient.h \
68 PPP/pppObsPool.h PPP/pppStation.h PPP/pppFilter.h \
69 PPP/pppEphPool.h PPP/pppModel.h PPP/pppParlist.h \
70 PPP/pppSatObs.h PPP/pppRun.h PPP/pppCrdFile.h
71
72HEADERS += serial/qextserialbase.h serial/qextserialport.h
73unix:HEADERS += serial/posix_qextserialport.h
74win32:HEADERS += serial/win_qextserialport.h
75
76SOURCES = bncgetthread.cpp bncwindow.cpp bnctabledlg.cpp \
77 bnccaster.cpp bncrinex.cpp bnccore.cpp bncutils.cpp \
78 bncconst.cpp bnchtml.cpp bnchlpdlg.cpp bnctableitem.cpp \
79 bnczerodecoder.cpp bncnetqueryv1.cpp bncnetqueryv2.cpp \
80 bncnetqueryrtp.cpp bncsettings.cpp latencychecker.cpp \
81 bncipport.cpp bncnetqueryv0.cpp bncnetqueryudp.cpp \
82 bncnetqueryudp0.cpp bncudpport.cpp \
83 bncserialport.cpp bncnetquerys.cpp bncfigure.cpp \
84 bncfigurelate.cpp bnctime.cpp \
85 bncfigureppp.cpp bncrawfile.cpp \
86 bncmap_svg.cpp bncantex.cpp \
87 bncephuser.cpp bncoutf.cpp bncclockrinex.cpp bncsp3.cpp \
88 bncbytescounter.cpp bncsslconfig.cpp reqcdlg.cpp \
89 ephemeris.cpp t_prn.cpp \
90 upload/bncrtnetdecoder.cpp upload/bncuploadcaster.cpp \
91 upload/bncrtnetuploadcaster.cpp upload/bnccustomtrafo.cpp \
92 upload/bncephuploadcaster.cpp qtfilechooser.cpp \
93 GPSDecoder.cpp RTCM/RTCM2.cpp RTCM/RTCM2Decoder.cpp \
94 RTCM/RTCM2_2021.cpp RTCM/rtcm_utils.cpp \
95 RTCM3/RTCM3Decoder.cpp RTCM3/rtcm3torinex/rtcm3torinex.c \
96 RTCM3/RTCM3coDecoder.cpp RTCM3/ephEncoder.cpp \
97 RTCM3/clock_and_orbit/clock_orbit_rtcm.c \
98 rinex/rnxobsfile.cpp \
99 rinex/rnxnavfile.cpp rinex/corrfile.cpp \
100 rinex/reqcedit.cpp rinex/reqcanalyze.cpp \
101 rinex/graphwin.cpp rinex/polarplot.cpp \
102 rinex/availplot.cpp rinex/eleplot.cpp \
103 rinex/dopplot.cpp \
104 PPP/pppOptions.cpp PPP/pppMain.cpp \
105 PPP/pppWidgets.cpp PPP/pppThread.cpp PPP/pppClient.cpp \
106 PPP/pppObsPool.cpp PPP/pppStation.cpp PPP/pppFilter.cpp \
107 PPP/pppEphPool.cpp PPP/pppModel.cpp PPP/pppParlist.cpp \
108 PPP/pppSatObs.cpp PPP/pppRun.cpp PPP/pppCrdFile.cpp
109
110SOURCES += serial/qextserialbase.cpp serial/qextserialport.cpp
111unix:SOURCES += serial/posix_qextserialport.cpp
112win32:SOURCES += serial/win_qextserialport.cpp
113
114RC_FILE = bnc.rc
115
116QT += network
117
118exists(combination/bnccomb.h) {
119 DEFINES += USE_COMBINATION
120 HEADERS += combination/bnccomb.h
121 SOURCES += combination/bnccomb.cpp
122}
123
124# Check QtWebKit Library Existence
125# --------------------------------
126win32 {
127 exists("$$[QT_INSTALL_BINS]/QtWebKit4.dll") {
128 DEFINES += QT_WEBKIT
129 }
130}
131
132unix {
133 exists("$$[QT_INSTALL_LIBS]/libQtWebKit.so") {
134 DEFINES += QT_WEBKIT
135 }
136}
137
138macx {
139 exists("$$[QT_INSTALL_LIBS]/QtWebKit.framework") {
140 DEFINES += QT_WEBKIT
141 }
142}
143
144contains(DEFINES, QT_WEBKIT) {
145 message("Configured with QtWebKit")
146 QT += webkit
147 HEADERS += map/bncmapwin.h
148 SOURCES += map/bncmapwin.cpp
149 OTHER_FILES += map/map_gm.html map/map_osm.html
150}
151else {
152 message("No QtWebKit")
153}
Note: See TracBrowser for help on using the repository browser.