source: ntrip/trunk/BNC/src/src.pri@ 5868

Last change on this file since 5868 was 5868, checked in by mervart, 8 years ago
File size: 6.5 KB
Line 
1
2DEFINES += NO_RTCM3_MAIN
3unix:DEFINES += _TTY_POSIX_
4win32:DEFINES += _TTY_WIN_
5
6RESOURCES += bnc.qrc
7
8QT += svg
9
10unix:QMAKE_CFLAGS_RELEASE -= -O2
11unix:QMAKE_CXXFLAGS_RELEASE -= -O2
12
13# Get rid of mingwm10.dll and libgcc_s_dw2-1.dll
14# ----------------------------------------------
15win32 {
16 QMAKE_LFLAGS += -static-libgcc
17 QMAKE_LFLAGS -= -mthreads
18 QMAKE_CXXFLAGS_EXCEPTIONS_ON -= -mthreads
19 QMAKE_LFLAGS_EXCEPTIONS_ON -= -mthreads
20}
21
22debug:OBJECTS_DIR=.obj/debug
23debug:MOC_DIR=.moc/debug
24release:OBJECTS_DIR=.obj/release
25release:MOC_DIR=.moc/release
26
27# Include Path
28# ------------
29INCLUDEPATH += . ../newmat ./RTCM3 ./RTCM3/clock_and_orbit ./RTCM3/rtcm3torinex \
30 ../qwt ../qwtpolar
31
32# Additional Libraries
33# --------------------
34unix:LIBS += -L../newmat -lnewmat -L../qwt -L../qwtpolar -lqwtpolar -lqwt
35win32:LIBS += -L../newmat/release -L../qwt/release -L../qwtpolar/release \
36 -lnewmat -lqwtpolar -lqwt
37
38HEADERS = bnchelp.html bncgetthread.h bncwindow.h bnctabledlg.h \
39 bnccaster.h bncrinex.h bnccore.h bncutils.h bnchlpdlg.h \
40 bncconst.h bnchtml.h bnctableitem.h bnczerodecoder.h \
41 bncnetquery.h bncnetqueryv1.h bncnetqueryv2.h \
42 bncnetqueryrtp.h bncsettings.h latencychecker.h \
43 bncipport.h bncnetqueryv0.h bncnetqueryudp.h \
44 bncnetqueryudp0.h bncudpport.h bnctime.h \
45 bncserialport.h bncnetquerys.h bncfigure.h \
46 bncfigurelate.h bncversion.h \
47 bancroft.h bncfigureppp.h bncrawfile.h \
48 bncmap.h bncantex.h \
49 bncephuser.h bncoutf.h bncclockrinex.h bncsp3.h \
50 bncbytescounter.h bncsslconfig.h reqcdlg.h \
51 upload/bncrtnetdecoder.h upload/bncuploadcaster.h \
52 ephemeris.h timeutils.h t_prn.h \
53 upload/bncrtnetuploadcaster.h upload/bnccustomtrafo.h \
54 upload/bncephuploadcaster.h bnccomb.h qtfilechooser.h \
55 GPSDecoder.h RTCM/RTCM2.h RTCM/RTCM2Decoder.h \
56 RTCM/RTCM2_2021.h RTCM/rtcm_utils.h \
57 RTCM3/RTCM3Decoder.h RTCM3/rtcm3torinex/rtcm3torinex.h \
58 RTCM3/RTCM3coDecoder.h RTCM3/ephEncoder.h \
59 RTCM3/clock_and_orbit/clock_orbit_rtcm.h \
60 PPP/pppInclude.h PPP/pppOptions.h PPP/pppMain.h \
61 PPP/pppWidgets.h PPP/pppThread.h PPP/pppClient.h \
62 PPP/pppObsPool.h PPP/pppStation.h PPP/pppFilter.h \
63 PPP/pppEphPool.h PPP/pppModel.h PPP/pppParlist.h \
64 PPP/pppSatObs.h PPP/pppRunRealTime.h
65
66HEADERS += serial/qextserialbase.h serial/qextserialport.h
67unix:HEADERS += serial/posix_qextserialport.h
68win32:HEADERS += serial/win_qextserialport.h
69
70SOURCES = bncgetthread.cpp bncwindow.cpp bnctabledlg.cpp \
71 bnccaster.cpp bncrinex.cpp bnccore.cpp bncutils.cpp \
72 bncconst.cpp bnchtml.cpp bnchlpdlg.cpp bnctableitem.cpp \
73 bnczerodecoder.cpp bncnetqueryv1.cpp bncnetqueryv2.cpp \
74 bncnetqueryrtp.cpp bncsettings.cpp latencychecker.cpp \
75 bncipport.cpp bncnetqueryv0.cpp bncnetqueryudp.cpp \
76 bncnetqueryudp0.cpp bncudpport.cpp \
77 bncserialport.cpp bncnetquerys.cpp bncfigure.cpp \
78 bncfigurelate.cpp bnctime.cpp \
79 bancroft.cpp bncfigureppp.cpp bncrawfile.cpp \
80 bncmap_svg.cpp bncantex.cpp \
81 bncephuser.cpp bncoutf.cpp bncclockrinex.cpp bncsp3.cpp \
82 bncbytescounter.cpp bncsslconfig.cpp reqcdlg.cpp \
83 ephemeris.cpp timeutils.cpp t_prn.cpp \
84 upload/bncrtnetdecoder.cpp upload/bncuploadcaster.cpp \
85 upload/bncrtnetuploadcaster.cpp upload/bnccustomtrafo.cpp \
86 upload/bncephuploadcaster.cpp qtfilechooser.cpp \
87 GPSDecoder.cpp RTCM/RTCM2.cpp RTCM/RTCM2Decoder.cpp \
88 RTCM/RTCM2_2021.cpp RTCM/rtcm_utils.cpp \
89 RTCM3/RTCM3Decoder.cpp RTCM3/rtcm3torinex/rtcm3torinex.c \
90 RTCM3/RTCM3coDecoder.cpp RTCM3/ephEncoder.cpp \
91 RTCM3/clock_and_orbit/clock_orbit_rtcm.c \
92 PPP/pppOptions.cpp PPP/pppMain.cpp \
93 PPP/pppWidgets.cpp PPP/pppThread.cpp PPP/pppClient.cpp \
94 PPP/pppObsPool.cpp PPP/pppStation.cpp PPP/pppFilter.cpp \
95 PPP/pppEphPool.cpp PPP/pppModel.cpp PPP/pppParlist.cpp \
96 PPP/pppSatObs.cpp PPP/pppRunRealTime.cpp
97
98SOURCES += serial/qextserialbase.cpp serial/qextserialport.cpp
99unix:SOURCES += serial/posix_qextserialport.cpp
100win32:SOURCES += serial/win_qextserialport.cpp
101
102RC_FILE = bnc.rc
103
104QT += network
105
106exists(combination/bnccomb.h) {
107 DEFINES += USE_COMBINATION
108 HEADERS += combination/bnccomb.h
109 SOURCES += combination/bnccomb.cpp
110}
111
112exists(rinex/rnxobsfile.h) {
113 DEFINES += USE_POSTPROCESSING
114 HEADERS += rinex/rnxobsfile.h \
115 rinex/rnxnavfile.h rinex/corrfile.h \
116 rinex/reqcedit.h rinex/reqcanalyze.h \
117 rinex/graphwin.h rinex/polarplot.h \
118 rinex/availplot.h rinex/eleplot.h \
119 rinex/dopplot.h
120 SOURCES += rinex/rnxobsfile.cpp \
121 rinex/rnxnavfile.cpp rinex/corrfile.cpp \
122 rinex/reqcedit.cpp rinex/reqcanalyze.cpp \
123 rinex/graphwin.cpp rinex/polarplot.cpp \
124 rinex/availplot.cpp rinex/eleplot.cpp \
125 rinex/dopplot.cpp
126}
127
128# Check QtWebKit Library Existence
129# --------------------------------
130win32 {
131 exists("$$[QT_INSTALL_BINS]/QtWebKit4.dll") {
132 DEFINES += QT_WEBKIT
133 }
134}
135
136unix {
137 exists("$$[QT_INSTALL_LIBS]/libQtWebKit.so") {
138 DEFINES += QT_WEBKIT
139 }
140}
141
142macx {
143 exists("$$[QT_INSTALL_LIBS]/QtWebKit.framework") {
144 DEFINES += QT_WEBKIT
145 }
146}
147
148contains(DEFINES, QT_WEBKIT) {
149 message("Configured with QtWebKit")
150 QT += webkit
151 HEADERS += map/bncmapwin.h
152 SOURCES += map/bncmapwin.cpp
153 OTHER_FILES += map/map_gm.html map/map_osm.html
154}
155else {
156 message("No QtWebKit")
157}
Note: See TracBrowser for help on using the repository browser.