source: ntrip/trunk/BNC/src/src.pri@ 5199

Last change on this file since 5199 was 5199, checked in by mervart, 9 years ago
File size: 6.3 KB
Line 
1
2DEFINES += NO_RTCM3_MAIN
3unix:DEFINES += _TTY_POSIX_
4win32:DEFINES += _TTY_WIN_
5
6RESOURCES += bnc.qrc
7
8QT += svg
9
10unix:QMAKE_CFLAGS_RELEASE -= -O2
11unix:QMAKE_CXXFLAGS_RELEASE -= -O2
12
13# Get rid of mingwm10.dll and libgcc_s_dw2-1.dll
14# ----------------------------------------------
15win32 {
16 QMAKE_LFLAGS += -static-libgcc
17 QMAKE_LFLAGS -= -mthreads
18 QMAKE_CXXFLAGS_EXCEPTIONS_ON -= -mthreads
19 QMAKE_LFLAGS_EXCEPTIONS_ON -= -mthreads
20}
21
22debug:OBJECTS_DIR=.obj/debug
23debug:MOC_DIR=.moc/debug
24release:OBJECTS_DIR=.obj/release
25release:MOC_DIR=.moc/release
26
27# Include Path
28# ------------
29INCLUDEPATH += . ../newmat ./RTCM3 ./RTCM3/clock_and_orbit ./RTCM3/rtcm3torinex \
30 ../qwt ../qwtpolar
31
32# Additional Libraries
33# --------------------
34unix:LIBS += -L../newmat -lnewmat -L../qwt -L../qwtpolar -lqwtpolar -lqwt
35win32:LIBS += -L../newmat/release -L../qwt/release -L../qwtpolar/release \
36 -lnewmat -lqwtpolar -lqwt
37
38HEADERS = bnchelp.html bncgetthread.h bncwindow.h bnctabledlg.h \
39 bnccaster.h bncrinex.h bnccore.h bncutils.h bnchlpdlg.h \
40 bncconst.h bnchtml.h bnctableitem.h bnczerodecoder.h \
41 bncnetquery.h bncnetqueryv1.h bncnetqueryv2.h \
42 bncnetqueryrtp.h bncsettings.h latencychecker.h \
43 bncipport.h bncnetqueryv0.h bncnetqueryudp.h \
44 bncnetqueryudp0.h bncudpport.h bnctime.h pppopt.h \
45 bncserialport.h bncnetquerys.h bncfigure.h \
46 bncfigurelate.h bncpppclient.h bncversion.h \
47 bancroft.h bncmodel.h bncfigureppp.h bncrawfile.h \
48 bnctides.h bncmap.h bncantex.h \
49 bncephuser.h bncoutf.h bncclockrinex.h bncsp3.h \
50 bncbytescounter.h bncsslconfig.h reqcdlg.h \
51 upload/bncrtnetdecoder.h upload/bncuploadcaster.h \
52 upload/bncrtnetuploadcaster.h upload/bnccustomtrafo.h \
53 upload/bncephuploadcaster.h bnccomb.h qtfilechooser.h \
54 RTCM/GPSDecoder.h RTCM/RTCM2.h RTCM/RTCM2Decoder.h \
55 RTCM/RTCM2_2021.h RTCM/rtcm_utils.h \
56 RTCM3/RTCM3Decoder.h RTCM3/rtcm3torinex/rtcm3torinex.h \
57 RTCM3/rtcm3torinex/rtcm3torinexsupport.h \
58 RTCM3/RTCM3coDecoder.h \
59 RTCM3/clock_and_orbit/clock_orbit_rtcm.h \
60 RTCM3/ephemeris.h RTCM3/timeutils.h \
61 GPSS/gpssDecoder.h GPSS/hassDecoder.h
62
63HEADERS += serial/qextserialbase.h serial/qextserialport.h
64unix:HEADERS += serial/posix_qextserialport.h
65win32:HEADERS += serial/win_qextserialport.h
66
67SOURCES = bncgetthread.cpp bncwindow.cpp bnctabledlg.cpp \
68 bnccaster.cpp bncrinex.cpp bnccore.cpp bncutils.cpp \
69 bncconst.cpp bnchtml.cpp bnchlpdlg.cpp bnctableitem.cpp \
70 bnczerodecoder.cpp bncnetqueryv1.cpp bncnetqueryv2.cpp \
71 bncnetqueryrtp.cpp bncsettings.cpp latencychecker.cpp \
72 bncipport.cpp bncnetqueryv0.cpp bncnetqueryudp.cpp \
73 bncnetqueryudp0.cpp bncudpport.cpp pppopt.cpp \
74 bncserialport.cpp bncnetquerys.cpp bncfigure.cpp \
75 bncfigurelate.cpp bncpppclient.cpp bnctime.cpp \
76 bancroft.cpp bncmodel.cpp bncfigureppp.cpp bncrawfile.cpp \
77 bnctides.cpp bncmap_svg.cpp bncantex.cpp \
78 bncephuser.cpp bncoutf.cpp bncclockrinex.cpp bncsp3.cpp \
79 bncbytescounter.cpp bncsslconfig.cpp reqcdlg.cpp \
80 upload/bncrtnetdecoder.cpp upload/bncuploadcaster.cpp \
81 upload/bncrtnetuploadcaster.cpp upload/bnccustomtrafo.cpp \
82 upload/bncephuploadcaster.cpp qtfilechooser.cpp \
83 RTCM/GPSDecoder.cpp RTCM/RTCM2.cpp RTCM/RTCM2Decoder.cpp \
84 RTCM/RTCM2_2021.cpp RTCM/rtcm_utils.cpp \
85 RTCM3/RTCM3Decoder.cpp RTCM3/rtcm3torinex/rtcm3torinex.c \
86 RTCM3/rtcm3torinex/rtcm3torinexsupport.c \
87 RTCM3/RTCM3coDecoder.cpp \
88 RTCM3/clock_and_orbit/clock_orbit_rtcm.c \
89 RTCM3/ephemeris.cpp RTCM3/timeutils.cpp \
90 GPSS/gpssDecoder.cpp GPSS/hassDecoder.cpp
91
92SOURCES += serial/qextserialbase.cpp serial/qextserialport.cpp
93unix:SOURCES += serial/posix_qextserialport.cpp
94win32:SOURCES += serial/win_qextserialport.cpp
95
96RC_FILE = bnc.rc
97
98QT += network
99
100exists(combination/bnccomb.h) {
101 DEFINES += USE_COMBINATION
102 HEADERS += combination/bnccomb.h
103 SOURCES += combination/bnccomb.cpp
104}
105
106exists(rinex/bncpostprocess.h) {
107 DEFINES += USE_POSTPROCESSING
108 HEADERS += rinex/bncpostprocess.h rinex/rnxobsfile.h \
109 rinex/rnxnavfile.h rinex/corrfile.h \
110 rinex/reqcedit.h rinex/reqcanalyze.h \
111 rinex/graphwin.h rinex/polarplot.h \
112 rinex/availplot.h rinex/eleplot.h \
113 rinex/dopplot.h
114 SOURCES += rinex/bncpostprocess.cpp rinex/rnxobsfile.cpp \
115 rinex/rnxnavfile.cpp rinex/corrfile.cpp \
116 rinex/reqcedit.cpp rinex/reqcanalyze.cpp \
117 rinex/graphwin.cpp rinex/polarplot.cpp \
118 rinex/availplot.cpp rinex/eleplot.cpp \
119 rinex/dopplot.cpp
120}
121
122# Link to a 3rd-part library (test)
123# ---------------------------------
124# use_RTRover = true
125
126equals(use_RTRover, true) {
127 DEFINES += RTROVER_INTERFACE
128 HEADERS += RTRover/bncrtrover.h
129 SOURCES += RTRover/bncrtrover.cpp
130 LIBS += -LRTRover -lRTRover
131 unix:LIBS += -Wl,-rpath,$$PWD/RTRover
132}
133
134
135# Check QtWebKit Library Existence
136# --------------------------------
137win32 {
138 exists("$$[QT_INSTALL_BINS]/QtWebKit4.dll") {
139 DEFINES += QT_WEBKIT
140 }
141}
142
143unix {
144 exists("$$[QT_INSTALL_LIBS]/libQtWebKit.so") {
145 DEFINES += QT_WEBKIT
146 }
147}
148
149contains(DEFINES, QT_WEBKIT) {
150 message("Configured with QtWebKit")
151 QT += webkit
152 HEADERS += map/bncmapwin.h
153 SOURCES += map/bncmapwin.cpp
154 OTHER_FILES += map/html/index.html map/html/mapview.js
155}
156else {
157 message("No QtWebKit")
158}
Note: See TracBrowser for help on using the repository browser.