source: ntrip/trunk/BNC/src/src.pri@ 10554

Last change on this file since 10554 was 10551, checked in by stuerze, 8 weeks ago

minor changes
File size: 7.4 KB
Line 
1
2unix:DEFINES += _TTY_POSIX_
3win32:DEFINES += _TTY_WIN_
4
5RESOURCES += bnc.qrc
6
7QT += svg
8QT += printsupport
9QT += widgets
10QT += core
11
12unix:QMAKE_CFLAGS_RELEASE -= -O2
13unix:QMAKE_CXXFLAGS_RELEASE -= -O2
14
15debug:OBJECTS_DIR=.obj/debug
16debug:MOC_DIR=.moc/debug
17release:OBJECTS_DIR=.obj/release
18release:MOC_DIR=.moc/release
19
20release:DEFINES += SPLITBLOCK
21debug:DEFINES += SPLITBLOCK
22#debug:DEFINES += BNC_DEBUG_OBS
23#debug:DEFINES += BNC_DEBUG_BCE
24#debug:DEFINES += BNC_DEBUG_PPP
25#debug:DEFINES += BNC_DEBUG_SSR
26#debug:DEFINES += BNC_DEBUG_CMB
27#debug:DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x050F00
28
29!versionAtLeast(QT_VERSION, 5.15.0):error("Use at least Qt version 5.15.0")
30
31# Include Path
32# ------------
33INCLUDEPATH += . ../newmat ./RTCM3 ./RTCM3/clock_and_orbit ./RTCM \
34 ../qwt ../qwtpolar
35
36# Additional Libraries
37# --------------------
38unix:LIBS += -L../newmat -lnewmat -L../qwt -L../qwtpolar -lqwtpolar -lqwt
39win32:LIBS += -L../newmat/release -L../qwt/release -L../qwtpolar/release \
40 -lnewmat -lqwtpolar -lqwt
41
42HEADERS = bnchelp.html bncgetthread.h bncwindow.h bnctabledlg.h \
43 bnccaster.h bncrinex.h bnccore.h bncutils.h bnchlpdlg.h \
44 bncconst.h bnchtml.h bnctableitem.h bnczerodecoder.h \
45 bncnetquery.h bncnetqueryv1.h bncnetqueryv2.h \
46 bncnetqueryrtp.h bncsettings.h latencychecker.h \
47 bncipport.h bncnetqueryv0.h bncnetqueryudp.h \
48 bncnetqueryudp0.h bncudpport.h bnctime.h \
49 bncserialport.h bncnetquerys.h bncfigure.h \
50 bncfigurelate.h bncversion.h \
51 bncfigureppp.h bncrawfile.h \
52 bncmap.h bncantex.h bncephuser.h \
53 bncoutf.h bncclockrinex.h bncsp3.h bncsinextro.h \
54 bncbiassinex.h \
55 bncbytescounter.h bncsslconfig.h reqcdlg.h \
56 upload/bncrtnetdecoder.h upload/bncuploadcaster.h \
57 ephemeris.h t_prn.h satObs.h \
58 upload/bncrtnetuploadcaster.h upload/bnccustomtrafo.h \
59 upload/bncephuploadcaster.h qtfilechooser.h \
60 GPSDecoder.h pppInclude.h pppWidgets.h pppModel.h \
61 pppMain.h pppRun.h pppOptions.h pppCrdFile.h pppThread.h \
62 RTCM/RTCM2.h RTCM/RTCM2Decoder.h \
63 RTCM/RTCM2_2021.h RTCM/rtcm_utils.h \
64 RTCM3/RTCM3Decoder.h RTCM3/bits.h RTCM3/gnss.h \
65 RTCM3/RTCM3coDecoder.h RTCM3/ephEncoder.h \
66 RTCM3/crs.h RTCM3/crsEncoder.h \
67 RTCM3/clock_and_orbit/clock_orbit.h \
68 RTCM3/clock_and_orbit/clock_orbit_igs.h \
69 RTCM3/clock_and_orbit/clock_orbit_rtcm.h \
70 rinex/rnxobsfile.h \
71 rinex/rnxnavfile.h rinex/corrfile.h \
72 rinex/reqcedit.h rinex/reqcanalyze.h \
73 rinex/graphwin.h rinex/polarplot.h \
74 rinex/availplot.h rinex/eleplot.h \
75 rinex/dopplot.h orbComp/sp3Comp.h \
76 combination/bnccomb.h combination/bncbiassnx.h
77
78HEADERS += serial/qextserialbase.h serial/qextserialport.h
79unix:HEADERS += serial/posix_qextserialport.h
80win32:HEADERS += serial/win_qextserialport.h
81
82SOURCES = bncgetthread.cpp bncwindow.cpp bnctabledlg.cpp \
83 bnccaster.cpp bncrinex.cpp bnccore.cpp bncutils.cpp \
84 bncconst.cpp bnchtml.cpp bnchlpdlg.cpp bnctableitem.cpp \
85 bnczerodecoder.cpp bncnetqueryv1.cpp bncnetqueryv2.cpp \
86 bncnetqueryrtp.cpp bncsettings.cpp latencychecker.cpp \
87 bncipport.cpp bncnetqueryv0.cpp bncnetqueryudp.cpp \
88 bncnetqueryudp0.cpp bncudpport.cpp \
89 bncserialport.cpp bncnetquerys.cpp bncfigure.cpp \
90 bncfigurelate.cpp bnctime.cpp \
91 bncfigureppp.cpp bncrawfile.cpp \
92 bncmap_svg.cpp bncantex.cpp bncephuser.cpp \
93 bncoutf.cpp bncclockrinex.cpp bncsp3.cpp bncsinextro.cpp \
94 bncbiassinex.cpp \
95 bncbytescounter.cpp bncsslconfig.cpp reqcdlg.cpp \
96 ephemeris.cpp t_prn.cpp satObs.cpp \
97 upload/bncrtnetdecoder.cpp upload/bncuploadcaster.cpp \
98 upload/bncrtnetuploadcaster.cpp upload/bnccustomtrafo.cpp \
99 upload/bncephuploadcaster.cpp qtfilechooser.cpp \
100 GPSDecoder.cpp pppWidgets.cpp pppModel.cpp \
101 pppMain.cpp pppRun.cpp pppOptions.cpp pppCrdFile.cpp \
102 pppThread.cpp \
103 RTCM/RTCM2.cpp RTCM/RTCM2Decoder.cpp \
104 RTCM/RTCM2_2021.cpp RTCM/rtcm_utils.cpp \
105 RTCM3/RTCM3Decoder.cpp \
106 RTCM3/RTCM3coDecoder.cpp RTCM3/ephEncoder.cpp \
107 RTCM3/crsEncoder.cpp \
108 RTCM3/clock_and_orbit/clock_orbit_igs.cpp \
109 RTCM3/clock_and_orbit/clock_orbit_rtcm.cpp \
110 rinex/rnxobsfile.cpp \
111 rinex/rnxnavfile.cpp rinex/corrfile.cpp \
112 rinex/reqcedit.cpp rinex/reqcanalyze.cpp \
113 rinex/graphwin.cpp rinex/polarplot.cpp \
114 rinex/availplot.cpp rinex/eleplot.cpp \
115 rinex/dopplot.cpp orbComp/sp3Comp.cpp \
116 combination/bnccomb.cpp combination/bncbiassnx.cpp
117
118SOURCES += serial/qextserialbase.cpp serial/qextserialport.cpp
119unix:SOURCES += serial/posix_qextserialport.cpp
120win32:SOURCES += serial/win_qextserialport.cpp
121
122RC_FILE = bnc.rc
123
124QT += network
125
126exists(PPP) {
127 INCLUDEPATH += PPP
128 DEFINES += USE_PPP
129 HEADERS += PPP/pppClient.h PPP/pppObsPool.h PPP/pppEphPool.h \
130 PPP/pppStation.h PPP/pppFilter.h PPP/pppParlist.h \
131 PPP/pppSatObs.h PPP/pppRefSat.h
132 SOURCES += PPP/pppClient.cpp PPP/pppObsPool.cpp PPP/pppEphPool.cpp \
133 PPP/pppStation.cpp PPP/pppFilter.cpp PPP/pppParlist.cpp \
134 PPP/pppSatObs.cpp
135}
136else {
137 INCLUDEPATH += PPP_SSR_I
138 DEFINES += USE_PPP_SSR_I
139 HEADERS += PPP_SSR_I/pppClient.h PPP_SSR_I/pppFilter.h PPP_SSR_I/pppUtils.h
140 SOURCES += PPP_SSR_I/pppClient.cpp PPP_SSR_I/pppFilter.cpp PPP_SSR_I/pppUtils.cpp
141}
142
143# Check QtWebEngineWidgets Library Existence
144# -----------------------------------------
145exists("$$[QT_INSTALL_LIBS]/*WebEngineWidgets*") {
146 DEFINES += QT_WEBENGINE
147 QT += webenginewidgets
148 message("Configured with QtWebEngine")
149}
150
151contains(DEFINES, QT_WEBENGINE) {
152 HEADERS += map/bncmapwin.h
153 SOURCES += map/bncmapwin.cpp
154 OTHER_FILES += map/map_osm.html
155}
156else {
157 message("QtWebEngineWidgets Library is not available")
158}
Note: See TracBrowser for help on using the repository browser.