source: ntrip/trunk/BNC/src/src.pri@ 9789

Last change on this file since 9789 was 9768, checked in by stuerze, 2 years ago

minor changes
File size: 7.4 KB
Line 
1
2unix:DEFINES += _TTY_POSIX_
3win32:DEFINES += _TTY_WIN_
4
5RESOURCES += bnc.qrc
6
7QT += svg
8QT += printsupport
9greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
10greaterThan(QT_MAJOR_VERSION, 4): QT += core
11
12unix:QMAKE_CFLAGS_RELEASE -= -O2
13unix:QMAKE_CXXFLAGS_RELEASE -= -O2
14
15# Get rid of mingwm10.dll and libgcc_s_dw2-1.dll
16# ----------------------------------------------
17win32 {
18 QMAKE_LFLAGS += -static-libgcc
19 QMAKE_LFLAGS -= -mthreads
20 QMAKE_CXXFLAGS_EXCEPTIONS_ON -= -mthreads
21 QMAKE_LFLAGS_EXCEPTIONS_ON -= -mthreads
22}
23
24debug:OBJECTS_DIR=.obj/debug
25debug:MOC_DIR=.moc/debug
26release:OBJECTS_DIR=.obj/release
27release:MOC_DIR=.moc/release
28
29release:DEFINES += SPLITBLOCK
30debug:DEFINES += SPLITBLOCK
31debug:DEFINES += BNC_DEBUG_BCEP
32#debug:DEFINES += BNC_DEBUG_PPP
33#debug:DEFINES += BNC_DEBUG_SSR
34#debug:DEFINES += BNC_DEBUG_CMB
35
36# Include Path
37# ------------
38INCLUDEPATH += . ../newmat ./RTCM3 ./RTCM3/clock_and_orbit ./RTCM \
39 ../qwt ../qwtpolar
40
41# Additional Libraries
42# --------------------
43unix:LIBS += -L../newmat -lnewmat -L../qwt -L../qwtpolar -lqwtpolar -lqwt
44win32:LIBS += -L../newmat/release -L../qwt/release -L../qwtpolar/release \
45 -lnewmat -lqwtpolar -lqwt
46
47HEADERS = bnchelp.html bncgetthread.h bncwindow.h bnctabledlg.h \
48 bnccaster.h bncrinex.h bnccore.h bncutils.h bnchlpdlg.h \
49 bncconst.h bnchtml.h bnctableitem.h bnczerodecoder.h \
50 bncnetquery.h bncnetqueryv1.h bncnetqueryv2.h \
51 bncnetqueryrtp.h bncsettings.h latencychecker.h \
52 bncipport.h bncnetqueryv0.h bncnetqueryudp.h \
53 bncnetqueryudp0.h bncudpport.h bnctime.h \
54 bncserialport.h bncnetquerys.h bncfigure.h \
55 bncfigurelate.h bncversion.h \
56 bncfigureppp.h bncrawfile.h \
57 bncmap.h bncantex.h bncephuser.h \
58 bncoutf.h bncclockrinex.h bncsp3.h bncsinextro.h \
59 bncbissinex.h \
60 bncbytescounter.h bncsslconfig.h reqcdlg.h \
61 upload/bncrtnetdecoder.h upload/bncuploadcaster.h \
62 ephemeris.h t_prn.h satObs.h \
63 upload/bncrtnetuploadcaster.h upload/bnccustomtrafo.h \
64 upload/bncephuploadcaster.h qtfilechooser.h \
65 GPSDecoder.h pppInclude.h pppWidgets.h pppModel.h \
66 pppMain.h pppRun.h pppOptions.h pppCrdFile.h pppThread.h \
67 RTCM/RTCM2.h RTCM/RTCM2Decoder.h \
68 RTCM/RTCM2_2021.h RTCM/rtcm_utils.h \
69 RTCM3/RTCM3Decoder.h RTCM3/bits.h RTCM3/gnss.h \
70 RTCM3/RTCM3coDecoder.h RTCM3/ephEncoder.h \
71 RTCM3/clock_and_orbit/clock_orbit.h \
72 RTCM3/clock_and_orbit/clock_orbit_igs.h \
73 RTCM3/clock_and_orbit/clock_orbit_rtcm.h \
74 rinex/rnxobsfile.h \
75 rinex/rnxnavfile.h rinex/corrfile.h \
76 rinex/reqcedit.h rinex/reqcanalyze.h \
77 rinex/graphwin.h rinex/polarplot.h \
78 rinex/availplot.h rinex/eleplot.h \
79 rinex/dopplot.h orbComp/sp3Comp.h \
80 combination/bnccomb.h combination/bncbiassnx.h
81
82HEADERS += serial/qextserialbase.h serial/qextserialport.h
83unix:HEADERS += serial/posix_qextserialport.h
84win32:HEADERS += serial/win_qextserialport.h
85
86SOURCES = bncgetthread.cpp bncwindow.cpp bnctabledlg.cpp \
87 bnccaster.cpp bncrinex.cpp bnccore.cpp bncutils.cpp \
88 bncconst.cpp bnchtml.cpp bnchlpdlg.cpp bnctableitem.cpp \
89 bnczerodecoder.cpp bncnetqueryv1.cpp bncnetqueryv2.cpp \
90 bncnetqueryrtp.cpp bncsettings.cpp latencychecker.cpp \
91 bncipport.cpp bncnetqueryv0.cpp bncnetqueryudp.cpp \
92 bncnetqueryudp0.cpp bncudpport.cpp \
93 bncserialport.cpp bncnetquerys.cpp bncfigure.cpp \
94 bncfigurelate.cpp bnctime.cpp \
95 bncfigureppp.cpp bncrawfile.cpp \
96 bncmap_svg.cpp bncantex.cpp bncephuser.cpp \
97 bncoutf.cpp bncclockrinex.cpp bncsp3.cpp bncsinextro.cpp \
98 bncbiassinex.cpp \
99 bncbytescounter.cpp bncsslconfig.cpp reqcdlg.cpp \
100 ephemeris.cpp t_prn.cpp satObs.cpp \
101 upload/bncrtnetdecoder.cpp upload/bncuploadcaster.cpp \
102 upload/bncrtnetuploadcaster.cpp upload/bnccustomtrafo.cpp \
103 upload/bncephuploadcaster.cpp qtfilechooser.cpp \
104 GPSDecoder.cpp pppWidgets.cpp pppModel.cpp \
105 pppMain.cpp pppRun.cpp pppOptions.cpp pppCrdFile.cpp \
106 pppThread.cpp \
107 RTCM/RTCM2.cpp RTCM/RTCM2Decoder.cpp \
108 RTCM/RTCM2_2021.cpp RTCM/rtcm_utils.cpp \
109 RTCM3/RTCM3Decoder.cpp \
110 RTCM3/RTCM3coDecoder.cpp RTCM3/ephEncoder.cpp \
111 RTCM3/clock_and_orbit/clock_orbit_igs.cpp \
112 RTCM3/clock_and_orbit/clock_orbit_rtcm.cpp \
113 rinex/rnxobsfile.cpp \
114 rinex/rnxnavfile.cpp rinex/corrfile.cpp \
115 rinex/reqcedit.cpp rinex/reqcanalyze.cpp \
116 rinex/graphwin.cpp rinex/polarplot.cpp \
117 rinex/availplot.cpp rinex/eleplot.cpp \
118 rinex/dopplot.cpp orbComp/sp3Comp.cpp \
119 combination/bnccomb.cpp combination/bncbiassnx.cpp
120
121SOURCES += serial/qextserialbase.cpp serial/qextserialport.cpp
122unix:SOURCES += serial/posix_qextserialport.cpp
123win32:SOURCES += serial/win_qextserialport.cpp
124
125RC_FILE = bnc.rc
126
127QT += network
128
129exists(PPP) {
130 INCLUDEPATH += PPP
131 DEFINES += USE_PPP
132 HEADERS += PPP/pppClient.h PPP/pppObsPool.h PPP/pppEphPool.h \
133 PPP/pppStation.h PPP/pppFilter.h PPP/pppParlist.h \
134 PPP/pppSatObs.h PPP/pppRefSat.h
135 SOURCES += PPP/pppClient.cpp PPP/pppObsPool.cpp PPP/pppEphPool.cpp \
136 PPP/pppStation.cpp PPP/pppFilter.cpp PPP/pppParlist.cpp \
137 PPP/pppSatObs.cpp
138}
139else {
140 INCLUDEPATH += PPP_SSR_I
141 DEFINES += USE_PPP_SSR_I
142 HEADERS += PPP_SSR_I/pppClient.h PPP_SSR_I/pppFilter.h PPP_SSR_I/pppUtils.h
143 SOURCES += PPP_SSR_I/pppClient.cpp PPP_SSR_I/pppFilter.cpp PPP_SSR_I/pppUtils.cpp
144}
145
146# Check QtWebEngineWidgets Library Existence
147# -----------------------------------------
148exists("$$[QT_INSTALL_LIBS]/*WebEngineWidgets*") {
149 DEFINES += QT_WEBENGINE
150 QT += webenginewidgets
151 message("Configured with QtWebEngine")
152}
153
154contains(DEFINES, QT_WEBENGINE) {
155 HEADERS += map/bncmapwin.h
156 SOURCES += map/bncmapwin.cpp
157 OTHER_FILES += map/map_osm.html
158}
159else {
160 message("QtWebEngineWidgets Library is not available")
161}
Note: See TracBrowser for help on using the repository browser.