source: ntrip/trunk/BNC/src/src.pri@ 9669

Last change on this file since 9669 was 9652, checked in by stuerze, 3 years ago

Bias SINEX file can be written now during SSR upload
File size: 7.4 KB
Line 
1
2unix:DEFINES += _TTY_POSIX_
3win32:DEFINES += _TTY_WIN_
4
5RESOURCES += bnc.qrc
6
7QT += svg
8QT += printsupport
9greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
10greaterThan(QT_MAJOR_VERSION, 4): QT += core
11
12unix:QMAKE_CFLAGS_RELEASE -= -O2
13unix:QMAKE_CXXFLAGS_RELEASE -= -O2
14
15# Get rid of mingwm10.dll and libgcc_s_dw2-1.dll
16# ----------------------------------------------
17win32 {
18 QMAKE_LFLAGS += -static-libgcc
19 QMAKE_LFLAGS -= -mthreads
20 QMAKE_CXXFLAGS_EXCEPTIONS_ON -= -mthreads
21 QMAKE_LFLAGS_EXCEPTIONS_ON -= -mthreads
22}
23
24debug:OBJECTS_DIR=.obj/debug
25debug:MOC_DIR=.moc/debug
26release:OBJECTS_DIR=.obj/release
27release:MOC_DIR=.moc/release
28
29release:DEFINES += BNC_DEBUG_BCEP
30release:DEFINES += SPLITBLOCK
31
32debug:DEFINES += BNC_DEBUG_BCEP
33debug:DEFINES += SPLITBLOCK
34#debug:DEFINES += BNC_DEBUG_PPP
35#debug:DEFINES += BNC_DEBUG_SSR
36
37# Include Path
38# ------------
39INCLUDEPATH += . ../newmat ./RTCM3 ./RTCM3/clock_and_orbit ./RTCM \
40 ../qwt ../qwtpolar
41
42# Additional Libraries
43# --------------------
44unix:LIBS += -L../newmat -lnewmat -L../qwt -L../qwtpolar -lqwtpolar -lqwt
45win32:LIBS += -L../newmat/release -L../qwt/release -L../qwtpolar/release \
46 -lnewmat -lqwtpolar -lqwt
47
48HEADERS = bnchelp.html bncgetthread.h bncwindow.h bnctabledlg.h \
49 bnccaster.h bncrinex.h bnccore.h bncutils.h bnchlpdlg.h \
50 bncconst.h bnchtml.h bnctableitem.h bnczerodecoder.h \
51 bncnetquery.h bncnetqueryv1.h bncnetqueryv2.h \
52 bncnetqueryrtp.h bncsettings.h latencychecker.h \
53 bncipport.h bncnetqueryv0.h bncnetqueryudp.h \
54 bncnetqueryudp0.h bncudpport.h bnctime.h \
55 bncserialport.h bncnetquerys.h bncfigure.h \
56 bncfigurelate.h bncversion.h \
57 bncfigureppp.h bncrawfile.h \
58 bncmap.h bncantex.h bncephuser.h \
59 bncoutf.h bncclockrinex.h bncsp3.h bncsinextro.h \
60 bncbissinex.h \
61 bncbytescounter.h bncsslconfig.h reqcdlg.h \
62 upload/bncrtnetdecoder.h upload/bncuploadcaster.h \
63 ephemeris.h t_prn.h satObs.h \
64 upload/bncrtnetuploadcaster.h upload/bnccustomtrafo.h \
65 upload/bncephuploadcaster.h qtfilechooser.h \
66 GPSDecoder.h pppInclude.h pppWidgets.h pppModel.h \
67 pppMain.h pppRun.h pppOptions.h pppCrdFile.h pppThread.h \
68 RTCM/RTCM2.h RTCM/RTCM2Decoder.h \
69 RTCM/RTCM2_2021.h RTCM/rtcm_utils.h \
70 RTCM3/RTCM3Decoder.h RTCM3/bits.h RTCM3/gnss.h \
71 RTCM3/RTCM3coDecoder.h RTCM3/ephEncoder.h \
72 RTCM3/clock_and_orbit/clock_orbit.h \
73 RTCM3/clock_and_orbit/clock_orbit_igs.h \
74 RTCM3/clock_and_orbit/clock_orbit_rtcm.h \
75 rinex/rnxobsfile.h \
76 rinex/rnxnavfile.h rinex/corrfile.h \
77 rinex/reqcedit.h rinex/reqcanalyze.h \
78 rinex/graphwin.h rinex/polarplot.h \
79 rinex/availplot.h rinex/eleplot.h \
80 rinex/dopplot.h orbComp/sp3Comp.h \
81 combination/bnccomb.h
82
83HEADERS += serial/qextserialbase.h serial/qextserialport.h
84unix:HEADERS += serial/posix_qextserialport.h
85win32:HEADERS += serial/win_qextserialport.h
86
87SOURCES = bncgetthread.cpp bncwindow.cpp bnctabledlg.cpp \
88 bnccaster.cpp bncrinex.cpp bnccore.cpp bncutils.cpp \
89 bncconst.cpp bnchtml.cpp bnchlpdlg.cpp bnctableitem.cpp \
90 bnczerodecoder.cpp bncnetqueryv1.cpp bncnetqueryv2.cpp \
91 bncnetqueryrtp.cpp bncsettings.cpp latencychecker.cpp \
92 bncipport.cpp bncnetqueryv0.cpp bncnetqueryudp.cpp \
93 bncnetqueryudp0.cpp bncudpport.cpp \
94 bncserialport.cpp bncnetquerys.cpp bncfigure.cpp \
95 bncfigurelate.cpp bnctime.cpp \
96 bncfigureppp.cpp bncrawfile.cpp \
97 bncmap_svg.cpp bncantex.cpp bncephuser.cpp \
98 bncoutf.cpp bncclockrinex.cpp bncsp3.cpp bncsinextro.cpp \
99 bncbiassinex.cpp \
100 bncbytescounter.cpp bncsslconfig.cpp reqcdlg.cpp \
101 ephemeris.cpp t_prn.cpp satObs.cpp \
102 upload/bncrtnetdecoder.cpp upload/bncuploadcaster.cpp \
103 upload/bncrtnetuploadcaster.cpp upload/bnccustomtrafo.cpp \
104 upload/bncephuploadcaster.cpp qtfilechooser.cpp \
105 GPSDecoder.cpp pppWidgets.cpp pppModel.cpp \
106 pppMain.cpp pppRun.cpp pppOptions.cpp pppCrdFile.cpp \
107 pppThread.cpp \
108 RTCM/RTCM2.cpp RTCM/RTCM2Decoder.cpp \
109 RTCM/RTCM2_2021.cpp RTCM/rtcm_utils.cpp \
110 RTCM3/RTCM3Decoder.cpp \
111 RTCM3/RTCM3coDecoder.cpp RTCM3/ephEncoder.cpp \
112 RTCM3/clock_and_orbit/clock_orbit_igs.cpp \
113 RTCM3/clock_and_orbit/clock_orbit_rtcm.cpp \
114 rinex/rnxobsfile.cpp \
115 rinex/rnxnavfile.cpp rinex/corrfile.cpp \
116 rinex/reqcedit.cpp rinex/reqcanalyze.cpp \
117 rinex/graphwin.cpp rinex/polarplot.cpp \
118 rinex/availplot.cpp rinex/eleplot.cpp \
119 rinex/dopplot.cpp orbComp/sp3Comp.cpp \
120 combination/bnccomb.cpp
121
122SOURCES += serial/qextserialbase.cpp serial/qextserialport.cpp
123unix:SOURCES += serial/posix_qextserialport.cpp
124win32:SOURCES += serial/win_qextserialport.cpp
125
126RC_FILE = bnc.rc
127
128QT += network
129
130exists(PPP) {
131 INCLUDEPATH += PPP
132 DEFINES += USE_PPP
133 HEADERS += PPP/pppClient.h PPP/pppObsPool.h PPP/pppEphPool.h \
134 PPP/pppStation.h PPP/pppFilter.h PPP/pppParlist.h \
135 PPP/pppSatObs.h PPP/pppRefSat.h
136 SOURCES += PPP/pppClient.cpp PPP/pppObsPool.cpp PPP/pppEphPool.cpp \
137 PPP/pppStation.cpp PPP/pppFilter.cpp PPP/pppParlist.cpp \
138 PPP/pppSatObs.cpp
139}
140else {
141 INCLUDEPATH += PPP_SSR_I
142 DEFINES += USE_PPP_SSR_I
143 HEADERS += PPP_SSR_I/pppClient.h PPP_SSR_I/pppFilter.h PPP_SSR_I/pppUtils.h
144 SOURCES += PPP_SSR_I/pppClient.cpp PPP_SSR_I/pppFilter.cpp PPP_SSR_I/pppUtils.cpp
145}
146
147# Check QtWebEngineWidgets Library Existence
148# -----------------------------------------
149exists("$$[QT_INSTALL_LIBS]/*WebEngineWidgets*") {
150 DEFINES += QT_WEBENGINE
151 QT += webenginewidgets
152 message("Configured with QtWebEngine")
153}
154
155contains(DEFINES, QT_WEBENGINE) {
156 HEADERS += map/bncmapwin.h
157 SOURCES += map/bncmapwin.cpp
158 OTHER_FILES += map/map_osm.html
159}
160else {
161 message("QtWebEngineWidgets Library is not available")
162}
Note: See TracBrowser for help on using the repository browser.