source: ntrip/branches/BNC_2.12/src/src.pri@ 9043

Last change on this file since 9043 was 9036, checked in by stuerze, 4 years ago

some modification to allow encoding and decoding of SSR corrections in RTCM-SSR and IGS-SSR formats
File size: 7.1 KB
Line 
1
2unix:DEFINES += _TTY_POSIX_
3win32:DEFINES += _TTY_WIN_
4
5RESOURCES += bnc.qrc
6
7QT += svg
8
9unix:QMAKE_CFLAGS_RELEASE -= -O2
10unix:QMAKE_CXXFLAGS_RELEASE -= -O2
11
12# Get rid of mingwm10.dll and libgcc_s_dw2-1.dll
13# ----------------------------------------------
14win32 {
15 QMAKE_LFLAGS += -static-libgcc
16 QMAKE_LFLAGS -= -mthreads
17 QMAKE_CXXFLAGS_EXCEPTIONS_ON -= -mthreads
18 QMAKE_LFLAGS_EXCEPTIONS_ON -= -mthreads
19}
20
21debug:OBJECTS_DIR=.obj/debug
22debug:MOC_DIR=.moc/debug
23release:OBJECTS_DIR=.obj/release
24release:MOC_DIR=.moc/release
25
26debug:DEFINES += BNC_DEBUG
27
28# Include Path
29# ------------
30INCLUDEPATH += . ../newmat ./RTCM3 ./RTCM3/clock_and_orbit ./RTCM \
31 ../qwt ../qwtpolar
32
33# Additional Libraries
34# --------------------
35unix:LIBS += -L../newmat -lnewmat -L../qwt -L../qwtpolar -lqwtpolar -lqwt
36win32:LIBS += -L../newmat/release -L../qwt/release -L../qwtpolar/release \
37 -lnewmat -lqwtpolar -lqwt
38
39HEADERS = bnchelp.html bncgetthread.h bncwindow.h bnctabledlg.h \
40 bnccaster.h bncrinex.h bnccore.h bncutils.h bnchlpdlg.h \
41 bncconst.h bnchtml.h bnctableitem.h bnczerodecoder.h \
42 bncnetquery.h bncnetqueryv1.h bncnetqueryv2.h \
43 bncnetqueryrtp.h bncsettings.h latencychecker.h \
44 bncipport.h bncnetqueryv0.h bncnetqueryudp.h \
45 bncnetqueryudp0.h bncudpport.h bnctime.h \
46 bncserialport.h bncnetquerys.h bncfigure.h \
47 bncfigurelate.h bncversion.h \
48 bncfigureppp.h bncrawfile.h \
49 bncmap.h bncantex.h bncephuser.h \
50 bncoutf.h bncclockrinex.h bncsp3.h bncsinextro.h \
51 bncbytescounter.h bncsslconfig.h reqcdlg.h \
52 upload/bncrtnetdecoder.h upload/bncuploadcaster.h \
53 ephemeris.h t_prn.h satObs.h \
54 upload/bncrtnetuploadcaster.h upload/bnccustomtrafo.h \
55 upload/bncephuploadcaster.h qtfilechooser.h \
56 GPSDecoder.h pppInclude.h pppWidgets.h pppModel.h \
57 pppMain.h pppRun.h pppOptions.h pppCrdFile.h pppThread.h \
58 RTCM/RTCM2.h RTCM/RTCM2Decoder.h \
59 RTCM/RTCM2_2021.h RTCM/rtcm_utils.h \
60 RTCM3/RTCM3Decoder.h RTCM3/bits.h RTCM3/gnss.h \
61 RTCM3/RTCM3coDecoder.h RTCM3/ephEncoder.h \
62 RTCM3/clock_and_orbit/clock_orbit.h \
63 RTCM3/clock_and_orbit/clock_orbit_igs.h \
64 RTCM3/clock_and_orbit/clock_orbit_rtcm.h \
65 rinex/rnxobsfile.h \
66 rinex/rnxnavfile.h rinex/corrfile.h \
67 rinex/reqcedit.h rinex/reqcanalyze.h \
68 rinex/graphwin.h rinex/polarplot.h \
69 rinex/availplot.h rinex/eleplot.h \
70 rinex/dopplot.h orbComp/sp3Comp.h \
71 combination/bnccomb.h
72
73HEADERS += serial/qextserialbase.h serial/qextserialport.h
74unix:HEADERS += serial/posix_qextserialport.h
75win32:HEADERS += serial/win_qextserialport.h
76
77SOURCES = bncgetthread.cpp bncwindow.cpp bnctabledlg.cpp \
78 bnccaster.cpp bncrinex.cpp bnccore.cpp bncutils.cpp \
79 bncconst.cpp bnchtml.cpp bnchlpdlg.cpp bnctableitem.cpp \
80 bnczerodecoder.cpp bncnetqueryv1.cpp bncnetqueryv2.cpp \
81 bncnetqueryrtp.cpp bncsettings.cpp latencychecker.cpp \
82 bncipport.cpp bncnetqueryv0.cpp bncnetqueryudp.cpp \
83 bncnetqueryudp0.cpp bncudpport.cpp \
84 bncserialport.cpp bncnetquerys.cpp bncfigure.cpp \
85 bncfigurelate.cpp bnctime.cpp \
86 bncfigureppp.cpp bncrawfile.cpp \
87 bncmap_svg.cpp bncantex.cpp bncephuser.cpp \
88 bncoutf.cpp bncclockrinex.cpp bncsp3.cpp bncsinextro.cpp \
89 bncbytescounter.cpp bncsslconfig.cpp reqcdlg.cpp \
90 ephemeris.cpp t_prn.cpp satObs.cpp \
91 upload/bncrtnetdecoder.cpp upload/bncuploadcaster.cpp \
92 upload/bncrtnetuploadcaster.cpp upload/bnccustomtrafo.cpp \
93 upload/bncephuploadcaster.cpp qtfilechooser.cpp \
94 GPSDecoder.cpp pppWidgets.cpp pppModel.cpp \
95 pppMain.cpp pppRun.cpp pppOptions.cpp pppCrdFile.cpp \
96 pppThread.cpp \
97 RTCM/RTCM2.cpp RTCM/RTCM2Decoder.cpp \
98 RTCM/RTCM2_2021.cpp RTCM/rtcm_utils.cpp \
99 RTCM3/RTCM3Decoder.cpp \
100 RTCM3/RTCM3coDecoder.cpp RTCM3/ephEncoder.cpp \
101 RTCM3/clock_and_orbit/clock_orbit_igs.cpp \
102 RTCM3/clock_and_orbit/clock_orbit_rtcm.cpp \
103 rinex/rnxobsfile.cpp \
104 rinex/rnxnavfile.cpp rinex/corrfile.cpp \
105 rinex/reqcedit.cpp rinex/reqcanalyze.cpp \
106 rinex/graphwin.cpp rinex/polarplot.cpp \
107 rinex/availplot.cpp rinex/eleplot.cpp \
108 rinex/dopplot.cpp orbComp/sp3Comp.cpp \
109 combination/bnccomb.cpp
110
111SOURCES += serial/qextserialbase.cpp serial/qextserialport.cpp
112unix:SOURCES += serial/posix_qextserialport.cpp
113win32:SOURCES += serial/win_qextserialport.cpp
114
115RC_FILE = bnc.rc
116
117QT += network
118
119exists(PPP) {
120 INCLUDEPATH += PPP
121 DEFINES += USE_PPP
122 HEADERS += PPP/pppClient.h PPP/pppObsPool.h PPP/pppEphPool.h \
123 PPP/pppStation.h PPP/pppFilter.h PPP/pppParlist.h \
124 PPP/pppSatObs.h
125 SOURCES += PPP/pppClient.cpp PPP/pppObsPool.cpp PPP/pppEphPool.cpp \
126 PPP/pppStation.cpp PPP/pppFilter.cpp PPP/pppParlist.cpp \
127 PPP/pppSatObs.cpp
128}
129else {
130 INCLUDEPATH += PPP_SSR_I
131 DEFINES += USE_PPP_SSR_I
132 HEADERS += PPP_SSR_I/pppClient.h PPP_SSR_I/pppFilter.h PPP_SSR_I/pppUtils.h
133 SOURCES += PPP_SSR_I/pppClient.cpp PPP_SSR_I/pppFilter.cpp PPP_SSR_I/pppUtils.cpp
134}
135
136# Check QtWebKit Library Existence
137# --------------------------------
138win32 {
139 exists("$$[QT_INSTALL_BINS]/QtWebKit4.dll") {
140 DEFINES += QT_WEBKIT
141 }
142}
143
144unix {
145 exists("$$[QT_INSTALL_LIBS]/libQtWebKit.so") {
146 DEFINES += QT_WEBKIT
147 }
148}
149
150macx {
151 exists("$$[QT_INSTALL_LIBS]/QtWebKit.framework") {
152 DEFINES += QT_WEBKIT
153 }
154}
155
156contains(DEFINES, QT_WEBKIT) {
157 message("Configured with QtWebKit")
158 QT += webkit
159 HEADERS += map/bncmapwin.h
160 SOURCES += map/bncmapwin.cpp
161 OTHER_FILES += map/map_gm.html map/map_osm.html
162}
163else {
164 message("No QtWebKit")
165}
Note: See TracBrowser for help on using the repository browser.