source: ntrip/trunk/BNC/src/src.pri@ 9386

Last change on this file since 9386 was 9386, checked in by stuerze, 3 years ago

update regarding PPP
File size: 7.2 KB
Line 
1
2unix:DEFINES += _TTY_POSIX_
3win32:DEFINES += _TTY_WIN_
4
5RESOURCES += bnc.qrc
6
7QT += svg
8QT += printsupport
9greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
10greaterThan(QT_MAJOR_VERSION, 4): QT += core
11
12unix:QMAKE_CFLAGS_RELEASE -= -O2
13unix:QMAKE_CXXFLAGS_RELEASE -= -O2
14
15# Get rid of mingwm10.dll and libgcc_s_dw2-1.dll
16# ----------------------------------------------
17win32 {
18 QMAKE_LFLAGS += -static-libgcc
19 QMAKE_LFLAGS -= -mthreads
20 QMAKE_CXXFLAGS_EXCEPTIONS_ON -= -mthreads
21 QMAKE_LFLAGS_EXCEPTIONS_ON -= -mthreads
22}
23
24debug:OBJECTS_DIR=.obj/debug
25debug:MOC_DIR=.moc/debug
26release:OBJECTS_DIR=.obj/release
27release:MOC_DIR=.moc/release
28
29
30debug:DEFINES += BNC_DEBUG_BCEP
31#debug:DEFINES += BNC_DEBUG_PPP
32#debug:DEFINES += BNC_DEBUG_SSR
33release:DEFINES += BNC_DEBUG_BCEP
34
35
36# Include Path
37# ------------
38INCLUDEPATH += . ../newmat ./RTCM3 ./RTCM3/clock_and_orbit ./RTCM \
39 ../qwt ../qwtpolar
40
41# Additional Libraries
42# --------------------
43unix:LIBS += -L../newmat -lnewmat -L../qwt -L../qwtpolar -lqwtpolar -lqwt
44win32:LIBS += -L../newmat/release -L../qwt/release -L../qwtpolar/release \
45 -lnewmat -lqwtpolar -lqwt
46
47HEADERS = bnchelp.html bncgetthread.h bncwindow.h bnctabledlg.h \
48 bnccaster.h bncrinex.h bnccore.h bncutils.h bnchlpdlg.h \
49 bncconst.h bnchtml.h bnctableitem.h bnczerodecoder.h \
50 bncnetquery.h bncnetqueryv1.h bncnetqueryv2.h \
51 bncnetqueryrtp.h bncsettings.h latencychecker.h \
52 bncipport.h bncnetqueryv0.h bncnetqueryudp.h \
53 bncnetqueryudp0.h bncudpport.h bnctime.h \
54 bncserialport.h bncnetquerys.h bncfigure.h \
55 bncfigurelate.h bncversion.h \
56 bncfigureppp.h bncrawfile.h \
57 bncmap.h bncantex.h bncephuser.h \
58 bncoutf.h bncclockrinex.h bncsp3.h bncsinextro.h \
59 bncbytescounter.h bncsslconfig.h reqcdlg.h \
60 upload/bncrtnetdecoder.h upload/bncuploadcaster.h \
61 ephemeris.h t_prn.h satObs.h \
62 upload/bncrtnetuploadcaster.h upload/bnccustomtrafo.h \
63 upload/bncephuploadcaster.h qtfilechooser.h \
64 GPSDecoder.h pppInclude.h pppWidgets.h pppModel.h \
65 pppMain.h pppRun.h pppOptions.h pppCrdFile.h pppThread.h \
66 RTCM/RTCM2.h RTCM/RTCM2Decoder.h \
67 RTCM/RTCM2_2021.h RTCM/rtcm_utils.h \
68 RTCM3/RTCM3Decoder.h RTCM3/bits.h RTCM3/gnss.h \
69 RTCM3/RTCM3coDecoder.h RTCM3/ephEncoder.h \
70 RTCM3/clock_and_orbit/clock_orbit.h \
71 RTCM3/clock_and_orbit/clock_orbit_igs.h \
72 RTCM3/clock_and_orbit/clock_orbit_rtcm.h \
73 rinex/rnxobsfile.h \
74 rinex/rnxnavfile.h rinex/corrfile.h \
75 rinex/reqcedit.h rinex/reqcanalyze.h \
76 rinex/graphwin.h rinex/polarplot.h \
77 rinex/availplot.h rinex/eleplot.h \
78 rinex/dopplot.h orbComp/sp3Comp.h \
79 combination/bnccomb.h
80
81HEADERS += serial/qextserialbase.h serial/qextserialport.h
82unix:HEADERS += serial/posix_qextserialport.h
83win32:HEADERS += serial/win_qextserialport.h
84
85SOURCES = bncgetthread.cpp bncwindow.cpp bnctabledlg.cpp \
86 bnccaster.cpp bncrinex.cpp bnccore.cpp bncutils.cpp \
87 bncconst.cpp bnchtml.cpp bnchlpdlg.cpp bnctableitem.cpp \
88 bnczerodecoder.cpp bncnetqueryv1.cpp bncnetqueryv2.cpp \
89 bncnetqueryrtp.cpp bncsettings.cpp latencychecker.cpp \
90 bncipport.cpp bncnetqueryv0.cpp bncnetqueryudp.cpp \
91 bncnetqueryudp0.cpp bncudpport.cpp \
92 bncserialport.cpp bncnetquerys.cpp bncfigure.cpp \
93 bncfigurelate.cpp bnctime.cpp \
94 bncfigureppp.cpp bncrawfile.cpp \
95 bncmap_svg.cpp bncantex.cpp bncephuser.cpp \
96 bncoutf.cpp bncclockrinex.cpp bncsp3.cpp bncsinextro.cpp \
97 bncbytescounter.cpp bncsslconfig.cpp reqcdlg.cpp \
98 ephemeris.cpp t_prn.cpp satObs.cpp \
99 upload/bncrtnetdecoder.cpp upload/bncuploadcaster.cpp \
100 upload/bncrtnetuploadcaster.cpp upload/bnccustomtrafo.cpp \
101 upload/bncephuploadcaster.cpp qtfilechooser.cpp \
102 GPSDecoder.cpp pppWidgets.cpp pppModel.cpp \
103 pppMain.cpp pppRun.cpp pppOptions.cpp pppCrdFile.cpp \
104 pppThread.cpp \
105 RTCM/RTCM2.cpp RTCM/RTCM2Decoder.cpp \
106 RTCM/RTCM2_2021.cpp RTCM/rtcm_utils.cpp \
107 RTCM3/RTCM3Decoder.cpp \
108 RTCM3/RTCM3coDecoder.cpp RTCM3/ephEncoder.cpp \
109 RTCM3/clock_and_orbit/clock_orbit_igs.cpp \
110 RTCM3/clock_and_orbit/clock_orbit_rtcm.cpp \
111 rinex/rnxobsfile.cpp \
112 rinex/rnxnavfile.cpp rinex/corrfile.cpp \
113 rinex/reqcedit.cpp rinex/reqcanalyze.cpp \
114 rinex/graphwin.cpp rinex/polarplot.cpp \
115 rinex/availplot.cpp rinex/eleplot.cpp \
116 rinex/dopplot.cpp orbComp/sp3Comp.cpp \
117 combination/bnccomb.cpp
118
119SOURCES += serial/qextserialbase.cpp serial/qextserialport.cpp
120unix:SOURCES += serial/posix_qextserialport.cpp
121win32:SOURCES += serial/win_qextserialport.cpp
122
123RC_FILE = bnc.rc
124
125QT += network
126
127exists(PPP) {
128 INCLUDEPATH += PPP
129 DEFINES += USE_PPP
130 HEADERS += PPP/pppClient.h PPP/pppObsPool.h PPP/pppEphPool.h \
131 PPP/pppStation.h PPP/pppFilter.h PPP/pppParlist.h \
132 PPP/pppSatObs.h PPP/pppRefSat.h
133 SOURCES += PPP/pppClient.cpp PPP/pppObsPool.cpp PPP/pppEphPool.cpp \
134 PPP/pppStation.cpp PPP/pppFilter.cpp PPP/pppParlist.cpp \
135 PPP/pppSatObs.cpp PPP/pppRefSat.cpp
136}
137else {
138 INCLUDEPATH += PPP_SSR_I
139 DEFINES += USE_PPP_SSR_I
140 HEADERS += PPP_SSR_I/pppClient.h PPP_SSR_I/pppFilter.h PPP_SSR_I/pppUtils.h
141 SOURCES += PPP_SSR_I/pppClient.cpp PPP_SSR_I/pppFilter.cpp PPP_SSR_I/pppUtils.cpp
142}
143
144# Check QtWebEngineWidgets Library Existence
145# -----------------------------------------
146exists("$$[QT_INSTALL_LIBS]/*WebEngineWidgets*") {
147 DEFINES += QT_WEBENGINE
148 QT += webenginewidgets
149 message("Configured with QtWebEngine")
150}
151
152contains(DEFINES, QT_WEBENGINE) {
153 HEADERS += map/bncmapwin.h
154 SOURCES += map/bncmapwin.cpp
155 OTHER_FILES += map/map_osm.html
156}
157else {
158 message("QtWebEngineWidgets Library is not available")
159}
Note: See TracBrowser for help on using the repository browser.