source: ntrip/trunk/BNC/src/src.pri@ 5355

Last change on this file since 5355 was 5355, checked in by mervart, 9 years ago
File size: 6.3 KB
Line 
1
2DEFINES += NO_RTCM3_MAIN
3unix:DEFINES += _TTY_POSIX_
4win32:DEFINES += _TTY_WIN_
5
6RESOURCES += bnc.qrc
7
8QT += svg
9
10unix:QMAKE_CFLAGS_RELEASE -= -O2
11unix:QMAKE_CXXFLAGS_RELEASE -= -O2
12
13# Get rid of mingwm10.dll and libgcc_s_dw2-1.dll
14# ----------------------------------------------
15win32 {
16 QMAKE_LFLAGS += -static-libgcc
17 QMAKE_LFLAGS -= -mthreads
18 QMAKE_CXXFLAGS_EXCEPTIONS_ON -= -mthreads
19 QMAKE_LFLAGS_EXCEPTIONS_ON -= -mthreads
20}
21
22debug:OBJECTS_DIR=.obj/debug
23debug:MOC_DIR=.moc/debug
24release:OBJECTS_DIR=.obj/release
25release:MOC_DIR=.moc/release
26
27# Include Path
28# ------------
29INCLUDEPATH += . ../newmat ./RTCM3 ./RTCM3/clock_and_orbit ./RTCM3/rtcm3torinex \
30 ../qwt ../qwtpolar
31
32# Additional Libraries
33# --------------------
34unix:LIBS += -L../newmat -lnewmat -L../qwt -L../qwtpolar -lqwtpolar -lqwt
35win32:LIBS += -L../newmat/release -L../qwt/release -L../qwtpolar/release \
36 -lnewmat -lqwtpolar -lqwt
37
38HEADERS = bnchelp.html bncgetthread.h bncwindow.h bnctabledlg.h \
39 bnccaster.h bncrinex.h bnccore.h bncutils.h bnchlpdlg.h \
40 bncconst.h bnchtml.h bnctableitem.h bnczerodecoder.h \
41 bncnetquery.h bncnetqueryv1.h bncnetqueryv2.h \
42 bncnetqueryrtp.h bncsettings.h latencychecker.h \
43 bncipport.h bncnetqueryv0.h bncnetqueryudp.h \
44 bncnetqueryudp0.h bncudpport.h bnctime.h pppopt.h \
45 bncserialport.h bncnetquerys.h bncfigure.h \
46 bncfigurelate.h bncpppclient.h bncversion.h \
47 bancroft.h bncmodel.h bncfigureppp.h bncrawfile.h \
48 bnctides.h bncmap.h bncantex.h \
49 bncephuser.h bncoutf.h bncclockrinex.h bncsp3.h \
50 bncbytescounter.h bncsslconfig.h reqcdlg.h \
51 upload/bncrtnetdecoder.h upload/bncuploadcaster.h \
52 upload/bncrtnetuploadcaster.h upload/bnccustomtrafo.h \
53 upload/bncephuploadcaster.h bnccomb.h qtfilechooser.h \
54 RTCM/GPSDecoder.h RTCM/RTCM2.h RTCM/RTCM2Decoder.h \
55 RTCM/RTCM2_2021.h RTCM/rtcm_utils.h \
56 RTCM3/RTCM3Decoder.h RTCM3/rtcm3torinex/rtcm3torinex.h \
57 RTCM3/RTCM3coDecoder.h \
58 RTCM3/clock_and_orbit/clock_orbit_rtcm.h \
59 RTCM3/ephemeris.h RTCM3/timeutils.h \
60 GPSS/gpssDecoder.h GPSS/hassDecoder.h
61
62HEADERS += serial/qextserialbase.h serial/qextserialport.h
63unix:HEADERS += serial/posix_qextserialport.h
64win32:HEADERS += serial/win_qextserialport.h
65
66SOURCES = bncgetthread.cpp bncwindow.cpp bnctabledlg.cpp \
67 bnccaster.cpp bncrinex.cpp bnccore.cpp bncutils.cpp \
68 bncconst.cpp bnchtml.cpp bnchlpdlg.cpp bnctableitem.cpp \
69 bnczerodecoder.cpp bncnetqueryv1.cpp bncnetqueryv2.cpp \
70 bncnetqueryrtp.cpp bncsettings.cpp latencychecker.cpp \
71 bncipport.cpp bncnetqueryv0.cpp bncnetqueryudp.cpp \
72 bncnetqueryudp0.cpp bncudpport.cpp pppopt.cpp \
73 bncserialport.cpp bncnetquerys.cpp bncfigure.cpp \
74 bncfigurelate.cpp bncpppclient.cpp bnctime.cpp \
75 bancroft.cpp bncmodel.cpp bncfigureppp.cpp bncrawfile.cpp \
76 bnctides.cpp bncmap_svg.cpp bncantex.cpp \
77 bncephuser.cpp bncoutf.cpp bncclockrinex.cpp bncsp3.cpp \
78 bncbytescounter.cpp bncsslconfig.cpp reqcdlg.cpp \
79 upload/bncrtnetdecoder.cpp upload/bncuploadcaster.cpp \
80 upload/bncrtnetuploadcaster.cpp upload/bnccustomtrafo.cpp \
81 upload/bncephuploadcaster.cpp qtfilechooser.cpp \
82 RTCM/GPSDecoder.cpp RTCM/RTCM2.cpp RTCM/RTCM2Decoder.cpp \
83 RTCM/RTCM2_2021.cpp RTCM/rtcm_utils.cpp \
84 RTCM3/RTCM3Decoder.cpp RTCM3/rtcm3torinex/rtcm3torinex.c \
85 RTCM3/RTCM3coDecoder.cpp \
86 RTCM3/clock_and_orbit/clock_orbit_rtcm.c \
87 RTCM3/ephemeris.cpp RTCM3/timeutils.cpp \
88 GPSS/gpssDecoder.cpp GPSS/hassDecoder.cpp
89
90SOURCES += serial/qextserialbase.cpp serial/qextserialport.cpp
91unix:SOURCES += serial/posix_qextserialport.cpp
92win32:SOURCES += serial/win_qextserialport.cpp
93
94RC_FILE = bnc.rc
95
96QT += network
97
98exists(combination/bnccomb.h) {
99 DEFINES += USE_COMBINATION
100 HEADERS += combination/bnccomb.h
101 SOURCES += combination/bnccomb.cpp
102}
103
104exists(rinex/bncpostprocess.h) {
105 DEFINES += USE_POSTPROCESSING
106 HEADERS += rinex/bncpostprocess.h rinex/rnxobsfile.h \
107 rinex/rnxnavfile.h rinex/corrfile.h \
108 rinex/reqcedit.h rinex/reqcanalyze.h \
109 rinex/graphwin.h rinex/polarplot.h \
110 rinex/availplot.h rinex/eleplot.h \
111 rinex/dopplot.h
112 SOURCES += rinex/bncpostprocess.cpp rinex/rnxobsfile.cpp \
113 rinex/rnxnavfile.cpp rinex/corrfile.cpp \
114 rinex/reqcedit.cpp rinex/reqcanalyze.cpp \
115 rinex/graphwin.cpp rinex/polarplot.cpp \
116 rinex/availplot.cpp rinex/eleplot.cpp \
117 rinex/dopplot.cpp
118}
119
120# Link to a 3rd-part library (test)
121# ---------------------------------
122# use_RTRover = true
123
124equals(use_RTRover, true) {
125 DEFINES += RTROVER_INTERFACE
126 HEADERS += RTRover/bncrtrover.h
127 SOURCES += RTRover/bncrtrover.cpp
128 LIBS += -LRTRover -lRTRover
129 unix:LIBS += -Wl,-rpath,$$PWD/RTRover
130}
131
132
133# Check QtWebKit Library Existence
134# --------------------------------
135win32 {
136 exists("$$[QT_INSTALL_BINS]/QtWebKit4.dll") {
137 DEFINES += QT_WEBKIT
138 }
139}
140
141unix {
142 exists("$$[QT_INSTALL_LIBS]/libQtWebKit.so") {
143 DEFINES += QT_WEBKIT
144 }
145}
146
147macx {
148 exists("$$[QT_INSTALL_LIBS]/QtWebKit.framework") {
149 DEFINES += QT_WEBKIT
150 }
151}
152
153contains(DEFINES, QT_WEBKIT) {
154 message("Configured with QtWebKit")
155 QT += webkit
156 HEADERS += map/bncmapwin.h
157 SOURCES += map/bncmapwin.cpp
158 OTHER_FILES += map/map_gm.html map/map_osm.html
159}
160else {
161 message("No QtWebKit")
162}
Note: See TracBrowser for help on using the repository browser.